Alternative to evaluating a string using a function - oracle

Question

I'm trying to output a list of records but some may not have a value in the subject column.
I have an altSubject column that would specify what to output instead.
simplified for example
insert all
into myTable
(id, subject, altSubject, partNumber, serialNumber, startDate, endDate)
values
(1, 'test',null,'xyz','123','1/1/2019', '1/5/2019')
into myTable
(id, subject, altSubject, partNumber, serialNumber, startDate, endDate)
values
(2, null, '''SN: '' || serialNumber','abc','789','1/1/2019', '1/5/2019')
output should look like:
subject | Part Number | Start Date | End Date
test | xyz | 1/1/2019 | 1/5/2019
SN: 789 | abc | 1/1/2019 | 1/5/2019
I've been able to do this using a case with a function below but the problem I'm having is it takes 5 minutes to run on a 40k row table.
select
...
...
case when altSubject is not null then
fAltSubject(id,altSubject)
else
subject
end subject
from
myTable
where
status = 'closed'
the function:
create or replace function fAltSubject
(pID in number
, pAltSubject in varchar2)
return varchar2
as
vNewSubject varchar2(400) := '';
begin
vSql := 'select ' ||
pAltSubject ||
' from
myTable
where
id = ' || pID;
execute immediate vSql
into
vNewSubject;
return vNewSubject;
end faltsubject;
Is there a better way to do this that doesn't take 5 minutes?
Thanks in advance.

Answer 1

"how to use a user defined mask in a column when the mask could be a combination of fields and text".
This is the best I can do and get good performance.
The table defines Subject, AltSubject and DisplaySubject.
A trigger sets the DisplaySubject based on the other two fields.
The trigger must reference the specific column names, so it needs to be regenerated every time columns are added. Maybe a nightly job?
create table myTable (
id number,
subject varchar2(64),
altSubject varchar2(128),
displaySubject varchar2(128),
partNumber varchar2(16),
serialNumber varchar2(16),
startDate date,
endDate date
);
create or replace procedure generate_mytable_trigger is
l_newline constant varchar2(1) := chr(10);
l_text clob := to_clob(
'create or replace trigger mytable_displaysubject
before insert or update on mytable
for each row
declare
lt_column_names sys.odcivarchar2list;
begin
if :new.subject is not null then
:new.altsubject := null;
:new.displaysubject := :new.subject;
return;
end if;
:new.displaysubject := :new.altsubject;
-- start lines to be generated');
l_end_text constant varchar2(4000) :=
'-- end lines to be generated
return;
end mytable_displaysubject;';
begin
for rec in (
select l_newline ||
':new.displaysubject := replace(:new.displaysubject, ''#'||column_name||'#'', :new.'||column_name||');'
as text
from user_tab_columns where table_name = 'MYTABLE'
and column_name not in ('SUBJECT','ALTSUBJECT','DISPLAYSUBJECT')
) loop
l_text := l_text || rec.text;
end loop;
l_text := l_text || l_newline || l_end_text;
execute immediate l_text;
end;
/
exec generate_mytable_trigger;
Now a little test:
insert into mytable(id, subject, altsubject, partnumber, serialnumber, startdate, enddate)
select 1, 'test',null,'xyz','123',sysdate, sysdate+1 from dual
union all
select 2, null,'PN: #PARTNUMBER#','abc','789',sysdate, sysdate+1 from dual
union all
select 3, null,'PN: #PARTNUMBER#, SN: #SERIALNUMBER#','qsdf','789',sysdate, sysdate+1 from dual
union all
select 3, null,'PN: #PARTNUMBER#, ??: #BADCOLUMN#','qsdf','789',sysdate, sysdate+1 from dual;
commit;
select subject, altsubject, displaysubject from mytable;
SUBJECT ALTSUBJECT DISPLAYSUBJECT
test test
PN: #PARTNUMBER# PN: abc
PN: #PARTNUMBER#, SN: #SERIALNUMBER# PN: qsdf, SN: 789
PN: #PARTNUMBER#, ??: #BADCOLUMN# PN: qsdf, ??: #BADCOLUMN#

Answer 2

You have a recent version of Oracle: congratulations. So use it: virtual columns!
create table myTable (
id number,
subject varchar2(32),
altSubject varchar2(64)
generated always as (case when subject is null then 'SN: '||serialnumber end),
partNumber varchar2(16),
serialNumber varchar2(16),
startDate date,
endDate date
);
insert into mytable(id, subject, partnumber, serialnumber, startdate, enddate)
select 1, 'test','xyz','123',sysdate, sysdate+1 from dual
union all
select 2, null,'abc','789',sysdate, sysdate+1 from dual;
select ID, coalesce(SUBJECT, ALTSUBJECT) subject,
PARTNUMBER, SERIALNUMBER, STARTDATE, ENDDATE
from mytable;
ID SUBJECT PARTNUMBER SERIALNUMBER STARTDATE ENDDATE
-- -------- ----------- ------------- ------------------- -------------------
1 test xyz 123 2019-12-18 13:09:10 2019-12-19 13:09:10
2 SN: 789 abc 789 2019-12-18 13:09:10 2019-12-19 13:09:10
That may very well be overkill. You could always get rid of the extra column and say:
select ID, coalesce(SUBJECT, 'SN: '||serialnumber) subject,
PARTNUMBER, SERIALNUMBER, STARTDATE, ENDDATE
from mytable;
Best regards,
Stew Ashton