subtract from the previous line - bash

Question

I am trying to subtract the previous group-line from the current group-line one in the 2nd column. For example, the following script is repeating 100s of times.
A
322 0.2
322 0.2
322 0.2
B
455 0.35
455 0.35
455 0.35
C
566 0.92
566 0.92
566 0.92
A
322 0.18
322 0.18
322 0.18
B
455 0.33
455 0.33
455 0.33
C
566 0.99
566 0.99
566 0.99
I want the starting point is A, that means the fraction of 0.2 will be kept the same for the first group and 0.18 for the second group. In other words, C-B then B-A. See the desired output.
A
322 0.2
322 0.2
322 0.2
B
455 0.15
455 0.15
455 0.15
C
566 0.57
566 0.57
566 0.57
A
322 0.18
322 0.18
322 0.18
B
455 0.15
455 0.15
455 0.15
C
566 0.66
566 0.66
566 0.66
I tried this code to print it in the third column but it seems to subtract from the previous line, not previous group.
awk '{$3 = $2 - prev2; prev2 = $2; print;}'

Answer 1

awk to the rescue!
based on the posted input/output and implicit assumptions...
$ awk '/^A/ {ia=1; c=0}
ia {a[c++]=$2}
/^[B-Z]/ {ia=c=0}
!ia && NF>1 {t=$2; $2-=a[++c]; a[c]=t}1' file
A
322 0.2
322 0.2
322 0.2
B
455 0.15
455 0.15
455 0.15
C
566 0.57
566 0.57
566 0.57
A
322 0.18
322 0.18
322 0.18
B
455 0.15
455 0.15
455 0.15
C
566 0.66
566 0.66
566 0.66
the records under each heading can be different, but assumed to the same number of records.
If your real input not represented by this sample you may need to tweak the conditions.
Explanation
/^A/ {ia=1; c=0} if the label starts with A, set A indicator ai, reset counter.
ia {a[c++]=$2} if in A, store values for each record
/^[B-Z]/ {ia=c=0} for other labels, reset in A and counter
!ia && NF>1 {t=$2; $2-=a[++c]; a[c]=t} if not in A and not a label (number of fields more than one), save the numerical value, offset previously saved value for the corresponding record, save the temp value as the new offset value for the record position.
1 print