CMake is successful, but make fails when linking - macos

Question

I am trying to compile my project on macOS with CMake. I have gstreamer installed via brew and I can access the include directory. For example this is the include directoy for gstreamer:
/usr/local/Cellar/gstreamer/1.16.2/include/gstreamer-1.0/
When running cmake with following CMakeLists.txt everything runs successfully, but make fails when I trying to link with following error:
[ 25%] Linking CXX executable multiviewer
ld: library not found for -lgstreamer-1.0
CMakeLists.txt:
cmake_minimum_required(VERSION 3.15)
project(application)
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTORCC ON)
find_package(Qt5Core REQUIRED)
find_package(Qt5Quick REQUIRED)
find_package(Qt5WebSockets REQUIRED)
# Required for GStreamer
find_package(PkgConfig)
# Look for GStreamer installation
pkg_check_modules(GST REQUIRED gstreamer-1.0)
add_executable(application
main.cpp qml.qrc server.cpp server.h
${PROTO_SRCS} ${PROTO_HDRS} client.cpp client.h)
# Qt5
target_link_libraries(application Qt5::Core Qt5::Quick Qt5::WebSockets)
# GStreamer
target_include_directories(application PUBLIC ${GST_INCLUDE_DIRS})
target_compile_options(application PUBLIC ${GST_CFLAGS})
target_link_libraries(application ${GST_LIBRARIES})
Here are the packages I've installed:
brew install pkg-config
brew install gstreamer
brew install gst-plugins-base
brew install gst-plugins-good
brew install gst-plugins-bad
brew install gst-plugins-ugly
brew install gst-libav
Output of pkg-config --cflags gstreamer-1.0:
-I/usr/local/Cellar/libffi/3.2.1/lib/libffi-3.2.1/include -I/usr/local/Cellar/gstreamer/1.16.2/include/gstreamer-1.0 -I/usr/local/Cellar/glib/2.62.4/include -I/usr/local/Cellar/glib/2.62.4/include/glib-2.0 -I/usr/local/Cellar/glib/2.62.4/lib/glib-2.0/include -I/usr/local/opt/gettext/include -I/usr/local/Cellar/pcre/8.43/include
Output of pkg-config --libs gstreamer-1.0:
-L/usr/local/Cellar/gstreamer/1.16.2/lib -L/usr/local/Cellar/glib/2.62.4/lib -L/usr/local/opt/gettext/lib -lgstreamer-1.0 -lgobject-2.0 -lglib-2.0 -lintl
Do I need something else to install or what am I doing wrong?

Answer 1

The error:
ld: library not found for -lgstreamer-1.0
indicates that the library gstreamer-1.0 was passed to the linker, but the linker doesn't know where to find it (likely because it does not reside in the typical system paths). It is up to CMake to provide the full path to the GST libraries. From the pkg_check_modules documentation, here are some of the library-related variables populated for a generic package XXX:
<XXX>_LIBRARIES:
only the libraries (without the ‘-l’)
<XXX>_LINK_LIBRARIES:
the libraries and their absolute paths
<XXX>_LIBRARY_DIRS:
the paths of the libraries (without the ‘-L’)
The GST_LIBRARIES variable will only list the library names (gstreamer-1.0;gobject-2.0;glib-2.0;intl), but in this case, we need to provide the library paths as well. So, change the target_link_libraries() call to use GST_LINK_LIBRARIES:
target_link_libraries(application PUBLIC ${GST_LINK_LIBRARIES})