AppleScript - wait for do shell script done - applescript

Question

I write a Command Line Tool to fetch movie information from IMDB. It's in JavaScript and called movinfo. I run it in AppleScript:
tell application "System Events"
set movT to "Back-to-the-future"
set exportPath to "export PATH=$PATH:/usr/local/bin:;"
set oriInfo to do shell script exportPath & "movinfo " & quoted form of movT
return oriInfo
end tell
It works great. But sometimes movinfo takes long time to fetch the information from the Internet. So I want to add a function to check if the fetching is done or not. I try "ignoring...end ignoring" structure firstly:
tell application "System Events"
ignoring application responses
set movT to "Back-to-the-future"
set exportPath to "export PATH=$PATH:/usr/local/bin:;"
set oriInfo to do shell script exportPath & "movinfo " & quoted form of movT
end ignoring
end tell
tell application "System Events"
repeat 30 times
try
return oriInfo
exit repeat
on error
delay 1
end try
end repeat
do shell script "killall System\\ Events"
end tell
But this doesn't work. Maybe I can do something with the Command Line Tool to do this job. But I really don't know too much about JavaScript, and CLI. I want to do this in AppleScript.
Hope someone can tell me what's wrong with the code, or how to do this in AS?

Answer 1

Note that I don't have the movinfo utility (you neglected to provide a link) so I can't test this, but it should work on face value.
First (as vadian pointed out in comments) you don't need the System Events tell blocks as you've used them, so I've restructured that. The trick here is to detach the movinfo utility so it runs as a process independent of the script, writing the movie info into a file at ~/movieInfo.txt. The script then recovers the process pid from the do shell script, and waits for the utility to end, using system events to test if a process with that pid is still running. When the process ends,
the script reads the info from the file back into the oriInfo variable. For questions about the unix tricks, see: Technote 2065.
-- set output file path
set movieInfoFile to POSIX path of (path to home folder from user domain) & "movieInfo.txt"
set movT to "Back-to-the-future"
set exportPath to "export PATH=$PATH:/usr/local/bin:;"
-- run and detach utility, returning its process id
set procID to do shell script exportPath & "movinfo " & quoted form of movT & " &> " & movieInfoFile & " & echo $!"
repeat 30 times
tell application "System Events"
-- test if pid is still active
set isStillRunning to count of (every process whose unix id is procID)
end tell
if isStillRunning = 0 then
--not active, so proceed
exit repeat
else
delay 1
end if
end repeat
-- pull info from file
set fp to open for access movieInfoFile
set oriInfo to read fp
close access fp