Converting AppleScript Date into an NSdate object in ASOBJC? - applescript

Question

So I have some AppleScriptObjC code that does some things with dates. One of the first things it does is convert todays date into an NSDate object.
set nowDate to current application's NSDate's |date|()
I'd like to be able to set nowDate to any date I choose. From everything I have read, up until 10.11 this was a very complex process. But in 10.11 it supposedly got easier. I couldn't actually find any examples on how it was easier.
What I'd really like is to be able to say
set aDate to current date
set day of aDate to "15"
set month of aDate to "5"
set year of aDate to "2020"
set hours of aDate to "13"
set minutes of aDate to "00"
set seconds of aDate to "00"
set nowDate to NSDate's aDate --or something simple like that
I also found this function that looks to be able to set a date to any date you would like, but I have not idea how to convert this into useful ASOBJC code (I fumbled around a bit with it, but got nowhere):
- (NSDate *)dateWithEra:(NSInteger)eraValue
year:(NSInteger)yearValue
month:(NSInteger)monthValue
day:(NSInteger)dayValue
hour:(NSInteger)hourValue
minute:(NSInteger)minuteValue
second:(NSInteger)secondValue
nanosecond:(NSInteger)nanosecondValue;
Bonus question... what is the integer value for the era we are in?

Answer 1

Although AppleScriptObjC will easily convert an NSDate to an AppleScript date, there isn't anything quite that simple for going the other way.
There is something quite simple: AppleScript date is implicitly bridged to NSDate when being used as a parameter so you can convert it easily with
use AppleScript version "2.5"
use framework "Foundation"
use scripting additions
set currentDate to current date
set cocoaDate to current application's NSDate's dateWithTimeInterval:0 sinceDate:currentDate
log cocoaDate

Answer 2

Although AppleScriptObjC will easily coerce an NSDate to an AppleScript date, there isn't anything quite that simple for going the other way. Cocoa has a ton of options for dates, so you will need to use a few statements to define what you want.
The conversion for your Objective-C method would be something like (don't forget the pipes around AppleScript terms):
use framework "Foundation"
use scripting additions
tell (current date) to set {theDay, theMonth, theYear, theHours, theMinutes, theSeconds} to {its day, its month as integer, its year, its hours, its minutes, its seconds}
set theCalendar to current application's NSCalendar's currentCalendar
theCalendar's dateWithEra:1 |year|:theYear |month|:theMonth |day|:theDay hour:theHours minute:theMinutes |second|:theSeconds nanosecond:0
You could also use NSDateFormatter to convert from an ISO date string:
tell ((current date) as «class isot» as string) to set dateString to it
set formatter to current application's NSDateFormatter's alloc's init
formatter's setDateFormat:"yyyy-MM-dd'T'HH:mm:ss"
# formatter's setLocale:(current application's NSLocale's alloc's initWithLocaleIdentifier:"en_US_POSIX")
formatter's dateFromString:dateString
For your bonus question, it depends on the calendar used, but for the Gregorian Calendar there are two eras, BCE/BC and CE/AD. From the Apple's Date and Time Guide, if you are using negative years for BCE, the era would be 0, otherwise it would be 1.