How can I determine if a cell is vertically merged in PowerPoint? - powerpoint

Question

I've looked all the properties & methods in the PowerPoint interfaces Table, Row, & Cell. While Cell has a way to split & merge cells, none have a way to determine if a cell is presently merged. Is there a way to do this?
We use the COM (not VSTO) API if that makes a difference.

Answer 1

If you are using Aspose.Slides for .NET, it will be easy to check if a table cell is merged. You would know all necessary information about merged cells. The following code example shows how you can do this.
for (int rowIndex = 0; rowIndex < table.Rows.Count; rowIndex++)
{
for (int columnIndex = 0; columnIndex < table.Columns.Count; columnIndex++)
{
ICell cell = table.Rows[rowIndex][columnIndex];
if (cell.IsMergedCell)
{
Console.WriteLine($"The merged cell [{rowIndex},{columnIndex}] was found.");
Console.WriteLine($"Row span: {cell.RowSpan}");
Console.WriteLine($"Column span: {cell.ColSpan}");
Console.WriteLine($"The first row index: {cell.FirstRowIndex}");
Console.WriteLine($"The first column index: {cell.FirstColumnIndex}");
Console.WriteLine();
}
}
}
I work as a Support Developer at Aspose.

Answer 2

In VBA, we can compare the height of the cell and the row. If they are different, it means the cell is merged vertically. The following function determines whether the given cell is merged vertically or horizontally.
'simply check if the cell is merged
Function IsMerged(oTbl As Table, rr As Integer, cc As Integer) As Boolean
Dim c As Cell
'the current cell
Set c = oTbl.Cell(rr, cc)
'Check the width and height
'horizonatally merged
If c.Shape.Width <> oTbl.Columns(cc).Width Then IsMerged = True
'vertically merged
If c.Shape.Height <> oTbl.Rows(rr).Height Then IsMerged = True
End Function
We can also identify if the cell is the Top-Left(first) cell of the merged area by following method:
Function isTopLeftCell(oTbl As Table, rr As Integer, cc As Integer) As Boolean
Dim i As Integer
With oTbl.Cell(rr, cc).Shape
'horizontally merged
If .Width <> oTbl.Columns(cc).Width Then
'count the left cells merged from the currnet cell
For i = 1 To cc - 1
If oTbl.Cell(rr, cc - i).Shape.Left <> .Left Then Exit For
Next i
'count the rows above
If i = 1 Then
For i = 1 To rr - 1
If oTbl.Cell(rr - i, cc).Shape.Top <> .Top Then Exit For
Next i
If i = 1 Then isTopLeftCell = True: Exit Function
End If
'vertically merged
ElseIf .Height <> oTbl.Rows(rr).Height Then
For i = 1 To rr - 1
If oTbl.Cell(rr - i, cc).Shape.Top <> .Top Then Exit For
Next i
If i = 1 Then isTopLeftCell = True: Exit Function
Else
'isTopLeftCell = False
End If
End With
End Function
The following returns the width(ww) and height(hh) of the merged area
'Returns the width and height of the merged area
Function getMergedArea(oTbl As Table, rr As Integer, cc As Integer, ByRef ww As Integer, ByRef hh As Integer)
Dim c As Cell
Dim i As Integer, j As Integer
Set c = oTbl.Cell(rr, cc)
'ww = 1: hh = 1
ww = c.Shape.Width / oTbl.Columns(cc).Width
hh = c.Shape.Height / oTbl.Rows(rr).Height
End Function
If you want get the index no. of the cell in the merged area:
(which is the result of my hard working!)
'Returns the index no. of the cell : top to bottom, left to right
Function getMergedIndex(oTbl As Table, rr As Integer, cc As Integer) As Integer
Dim c As Cell
Dim i As Integer, j As Integer, mc As Integer
Set c = oTbl.Cell(rr, cc)
'horizontally merged
If c.Shape.Width <> oTbl.Columns(cc).Width Then
'get the horizontal index
For i = 1 To cc - 1
If oTbl.Cell(rr, cc - i).Shape.Left <> c.Shape.Left Then Exit For
Next i
'get the merged row count above
For j = 1 To rr - 1
If oTbl.Cell(rr - j, cc).Shape.Top <> c.Shape.Top Then Exit For
Next j
'if merged both horizontally and vertically
If j > 1 Then
'get the column count of the merged cells above
mc = oTbl.Cell(rr - 1, cc).Shape.Width / oTbl.Columns(cc).Width
'For mc = 1 To oTbl.Columns.Count - cc
' If oTbl.Cell(rr - 1, cc + mc).Shape.Left <> c.Shape.Left Then Exit For
'Next mc
'mc = i + mc - 1
'add up to the merged cells above
getMergedIndex = (j - 1) * mc + i
Else
getMergedIndex = i
End If
'vertically merged
ElseIf c.Shape.Height <> oTbl.Rows(rr).Height Then
For i = 1 To rr - 1
If oTbl.Cell(rr - i, cc).Shape.Top <> c.Shape.Top Then Exit For
Next i
getMergedIndex = i
Else
'not merged
End If
End Function
''For example:
''[ ][ ][ ][ ][ ][ ][ ][ ][ ][ ]
''[ ][01][02][03][04][ ][ ][ ][ ][ ]
''[ ][05][06][07][08][ ][ ][ ][ ][ ]
''[ ][ ][01][02][03][04][01][02][ ][ ]
''[ ][ ][05][06][07][08][03][04][ ][ ]
''[ ][ ][ ][ ][ ][ ][05][06][ ][ ]
''[01][02][03][04][01][ ][07][08][01][02]
''[05][06][07][08][02][ ][ ][ ][03][04]
''[01][02][03][04][ ][ ][ ][ ][05][06]
''[05][06][07][08][ ][ ][ ][ ][07][08]
finally, check if two given cells are contained within a merged area
Function isMerged2(oTbl As Table, r1%, c1%, r2%, c2%) As Boolean
If oTbl.Cell(r1, c1).Shape.Left = oTbl.Cell(r2, c2).Shape.Left And _
oTbl.Cell(r1, c1).Shape.Top = oTbl.Cell(r2, c2).Shape.Top And _
oTbl.Cell(r1, c1).Shape.Width = oTbl.Cell(r2, c2).Shape.Width And _
oTbl.Cell(r1, c1).Shape.Height = oTbl.Cell(r2, c2).Shape.Height Then _
isMerged2 = True
End Function