Create custom page with NSIS - installation

Question

I'd like to create a custom page using nsis. Just text, at different heights and possibly some image. Something similar to what oracle does:
From the docs at "Custom Pages" this is the way a custom page should be created:
;--------------------------------
;Pages
Function CustomPageFunction
!insertmacro MUI_HEADER_TEXT "TITLE" "SUBTITLE"
FunctionEnd
!insertmacro MUI_PAGE_WELCOME
Page custom CustomPageFunction
I am looking for additional guidlines on how to create very basic custom installer pages, because unfortunately, no new page with "TITLE" and "SUBTITLE" is displayed after MUI_PAGE_WELCOME as if extra instructions need to be added. What am I missing?ž
UPDATE for setting image:
var Image
var ImageHandle
Function CustomPageFunction
; !insertmacro MUI_HEADER_TEXT "TITLE" "SUBTITLE"
nsDialogs::Create 1044
Pop $0
${NSD_CreateBitmap} 0 0 100% 100% ""
Pop $Image
${NSD_SetImage} $Image "C:\Users\User\Desktop\TrickyWays\test.png" $ImageHandle
${NSD_CreateLabel} 0 0 100% 40% "Hello, welcome to nsDialogs!"
Pop $0
nsDialogs::Show
${NSD_FreeImage} $ImageHandle
FunctionEnd

Answer 1

The documentation you linked to only talks about custom pages in relation to the MUI header text. There is a ... there in the function where you are supposed to put the actual custom page code. I will try to fix that part of the documentation.
A custom page requires a plug-in and the most popular one is probably nsDialogs. A custom page that does not call a plug-in is automatically skipped.
!include nsDialogs.nsh
!include mui2.nsh
Function myPageCreate
!insertmacro MUI_HEADER_TEXT "TITLE" "SUBTITLE"
nsDialogs::Create 1018
Pop $0
${If} $0 == error
Abort
${EndIf}
${NSD_CreateLabel} 0 0 100% 12u "Hello, welcome to nsDialogs!"
Pop $0
${NSD_CreateText} 0 13u 100% -13u "Type something here..."
Pop $0
nsDialogs::Show
FunctionEnd
!insertmacro MUI_PAGE_WELCOME
Page custom myPageCreate
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE English