Get logon username in elevated script with standard user account - windows

Question

In my batch script run within Windows 7, I have several IF clauses like:
IF "%USERNAME%"=="foo" GOTO bar
Unfortunately, when I run this batch script elevated with "Run as administrator" from the Context Menu, the %USERNAME% is always the administrator's username, not the username of the current active logon user.
The same applies to whoami in an elevated batch script.
QUERY USER gives me a list of all users currently logged on, not merely the one user I am looking for.
A standard user account, unlike an administrator account that can elevate from user group token to administrator group token while keeping the same user environment, actually loads the administrator account environment when "Run as administrator" is selected.
Is there a way to get the current active logon username instead of the administrators username?

Answer 1

WMIC ComputerSystem Get UserName
#echo off
setlocal
rem Get logon username without the leading "computername\" string.
set "user="
for /f "skip=1 tokens=1,* delims=\" %%A in (
'wmic computersystem get username ^|findstr /r /v "^$"'
) do for %%C in (%%~B) do if not defined user set "user=%%~C"
echo "%user%"
pause
Using the for /f option skip=1, as the 1st line is the UserName header that is not wanted. Delimit by \ as the value will be like computername\username and get the remainder in the 2nd token. Pipe to findstr to ignore empty lines. 2nd for loop will get the first value free of whitespace characters.
Piping wmic output to powershell to cleanup the output tests better than piping to findstr, and the use of a 2nd for loop is not needed.
#echo off
setlocal
rem Get logon username without the leading "computername\" string.
set "user="
for /f "skip=1 tokens=1,* delims=\" %%A in ('
wmic computersystem get username ^|
powershell -noprofile -command "$input.trim()"
') do set "user=%%~B"
echo "%user%"
pause
Use command /? for more help. Most commands in the code will display help with the /? argument at a Command Prompt.
Query User alias QUser
#echo off
setlocal
rem Get logon username.
set "user="
for /f %%A in ('quser^|findstr /b /c:">"') do set "user=%%~A"
if defined user if "%user:~0,1%" == ">" set "user=%user:~1%"
echo "%user%"
pause
The leading > in quser (an alias for query user) indicates the currently logged on username, not the administrator's username.
Use %user% instead of %username% where needed.
Notes:
Due to for /f loop getting username from the default option of token=1, if username contains a space or tab, then this will get only the characters that precede the space or tab.
On a 64 bit OS, quser.exe exists in System32, not in SysWOW64. A 32 bit cmd.exe on a 64 bit OS may not be recognized as a command.
References:
query user
Query User / QUSER