Partitioning a List using a List - applescript

Question

I'm working on a project which requires me to partition a list using a list. I've created a solution which works in some situations, but not every situation. Is anyone able to help me with the logic?
There's two lists. The sum of each list will always be equal. The first list (i.e. the partitionBy list) is used to partition the second list (i.e the inputList).
Here's a simplified example:
List A {3, 2, 4}
List B {2, 1, 1, 1, 3, 1}
The first item of List A is 3. The sum of the first and second items of List B = 3 (i.e 2 + 1). Create a list for those items
The second item of List A is 2. The sum of the third and fourth items of List B = 2 (i.e. 1 + 1). Create a list for those items
etc ...
Ideal result would be: {{2, 1}, {1, 1}, {3, 1}}
The code is currently in AppleScript, but I'd be happy to translate it to JavaScript, if that helps.
Here's the code w/ examples:
--Example 1 works as expected
set partitionBy1 to {4, 1, 9, 6, 2, 2} -- list to partition by
set inputList1 to {1, 1, 1, 1, 1, 2, 2, 2, 3, 3, 3, 1, 1, 1, 1} -- list to partition
-- required output: {{1, 1, 1, 1}, {1}, {2, 2, 2, 3}, {3, 3}, {1, 1}, {1, 1}}
-- actual output: {{1, 1, 1, 1}, {1}, {2, 2, 2, 3}, {3, 3}, {1, 1}, {1, 1}}
--Example 2 works as expected
set partitionBy2 to {4, 2, 8, 6, 2, 2}
set inputList2 to {1, 1, 1, 1, 1, 2, 2, 2, 3, 3, 3, 1, 1, 1, 1}
-- required output: {{1, 1, 1, 1}, {1, 1}, {1, 2, 2, 3}, {3, 3}, {1, 1}, {1, 1}}
-- actual output: {{1, 1, 1, 1}, {1, 1}, {1, 2, 2, 3}, {3, 3}, {1, 1}, {1, 1}}
--Example 3 does not work as expected
set partitionBy3 to {4, 1, 9, 1, 3, 6, 2, 2}
set inputList3 to {1, 1, 1, 1, 1, 2, 2, 2, 3, 4, 3, 3, 1, 1, 1, 1}
-- required output: {{1, 1, 1, 1}, {1}, {2, 2, 2, 3}, {1}, {3}, {3, 3}, {1, 1}, {1, 1}}
-- actual output: {{1, 1, 1, 1}, {1}, {2, 2, 2, 3}, {3}, {3}, {3, 3}, {1, 1}, {1, 1}}
partitionList(inputList3, partitionBy3)
on partitionList(inputList, partitionBy)
set partitionedList to {}
repeat with i from 1 to (count partitionBy)
set partitionNumber to item i of partitionBy
set runningTotal to 0
set intermediateList to {}
repeat with j from 1 to ((count inputList) - 1)
set inputNumber to item j of inputList
set runningTotal to runningTotal + inputNumber
if runningTotal = partitionNumber then
set end of partitionedList to (intermediateList & inputNumber)
set inputList to items (j + 1) thru -1 of inputList
exit repeat
else if runningTotal > partitionNumber then
set item j of inputList to (inputNumber - 1)
set inputList to (inputNumber - 1) & inputList
set end of partitionedList to (intermediateList & (inputNumber - 1))
set inputList to items (j + 1) thru -1 of inputList
exit repeat
else
set end of intermediateList to inputNumber
end if
end repeat
end repeat
set end of partitionedList to intermediateList & item -1 of inputList
return partitionedList
end partitionList

Answer 1

The problem is the linear incrementation of j.
In case of runningTotal > partitionNumber you have to assign the difference (or the remainder) to inputNumber and evaluate the next partition without incrementing j.
I replaced repeat with with repeat while, added an overflow variable to indicate that runningTotal is greater than partitionNumber and declared j as local variable to have full control.
on partitionList(inputList, partitionBy)
set partitionedList to {}
set j to 1
set overflow to false
repeat with i from 1 to (count partitionBy)
set partitionNumber to item i of partitionBy
set runningTotal to 0
set intermediateList to {}
repeat while j < (count inputList)
if overflow then
set overflow to false
else
set inputNumber to item j of inputList
end if
set runningTotal to runningTotal + inputNumber
if runningTotal = partitionNumber then
set end of partitionedList to (intermediateList & inputNumber)
set j to j + 1
exit repeat
else if runningTotal > partitionNumber then
set end of partitionedList to {partitionNumber}
set overflow to true
set inputNumber to runningTotal - partitionNumber
exit repeat
else
set end of intermediateList to inputNumber
set j to j + 1
end if
end repeat
end repeat
set end of partitionedList to intermediateList & item -1 of inputList
return partitionedList
end partitionList