ff Function created with compilation errors - oracle

Question

create or replace function cart_jaune(code in equipe.num_eq%type) return integer as
nb integer := 0;
begin
select count(*)
into nb
from sanctionner s, joueur j
where s.code_joueur = j.code_joueur
and j.num_eq = code
and s.type_catron like '%jaune%';
return nb;
end;
/

Answer 1

Depending on tool you use, you should check which error you got. Because, how is anyone supposed to assist? What works regardless of a tool is querying user_errors. For example:
SQL> create or replace function f_test return number is
2 begin
3 retval := 1; --> variable isn't declared, so - compilation will fail
4 return retval;
5 end;
6 /
Warning: Function created with compilation errors.
SQL> select line, position, text from user_errors where name = 'F_TEST' order by line, position;
LINE POSITION TEXT
----- --------- --------------------------------------------------
3 3 PLS-00201: identifier 'RETVAL' must be declared
3 3 PL/SQL: Statement ignored
4 3 PL/SQL: Statement ignored
4 10 PLS-00201: identifier 'RETVAL' must be declared
Or, in SQL*Plus:
SQL> show err
Errors for FUNCTION F_TEST:
LINE/COL ERROR
-------- -----------------------------------------------------------------
3/3 PL/SQL: Statement ignored
3/3 PLS-00201: identifier 'RETVAL' must be declared
4/3 PL/SQL: Statement ignored
4/10 PLS-00201: identifier 'RETVAL' must be declared
SQL>
So, sooner you tell us what's wrong, sooner we'll be able to help.
Meanwhile, I created sample tables you used in your function. Everything seems to be OK.
SQL> create table equipe(num_eq number);
Table created.
SQL> create table sanctionner (code_joueur number, type_catron varchar2(10));
Table created.
SQL> create table joueur (code_joueur number, num_eq number);
Table created.
Function: I didn't change anything, just formatted it a little bit:
SQL> create or replace function cart_jaune(code in equipe.num_eq%type)
2 return integer
3 as
4 nb integer := 0;
5 begin
6 select count(*)
7 into nb
8 from sanctionner s,
9 joueur j
10 where s.code_joueur = j.code_joueur
11 and j.num_eq = code
12 and s.type_catron like '%jaune%';
13
14 return nb;
15 end;
16 /
Function created.
Does it work?
SQL> select cart_jaune(1) from dual;
CART_JAUNE(1)
-------------
0
SQL>
Yes, it works.

Answer 2

You pass the code value with the type EQUIPE.NUM_EQ%TYPE but compare it to the JOUEUR.NUM_EQ column. Unless you have two tables with the columns with the same name and data type then you probably wanted to declare the type in the signature to be JOUEUR.NUM_EQ%TYPE:
create or replace function cart_jaune(code in joueur.num_eq%type) return integer as
nb integer := 0;
begin
select count(*)
into nb
from sanctionner s, joueur j
where s.code_joueur = j.code_joueur
and j.num_eq = code
and s.type_catron like '%jaune%';
return nb;
end;
/
db<>fiddle here

Answer 3

AS others said, you need to show the error. We shouldn't have to play a game of "Guess What's In My Pocket?"
That said, ansi JOIN syntax has been available for, what, 20 years? You should use it:
select count(*)
into nb
from sanctionner s,
join joueur j on s.code_joueur = j.code_joueur
where j.num_eq = code
and s.type_catron like '%jaune%';
Helps insure you account for all of the joins.

Answer 4

Since we're playing "guess my error message", here's mine:
In your SQL query, you refer to code:
and j.num_eq = code
Since you have not provided any alias for code, the SQL engine will first try to match it to a column in any of the tables listed in your FROM clause.
If, for example, sanctionner has a column code, that will be what the SQL engine will use here, i.e.:
select count(*)
into nb
from sanctionner s, joueur j
where s.code_joueur = j.code_joueur
and j.num_eq = s.code
and s.type_catron like '%jaune%';
Since you actually wanted it to bind your PL/SQL function parameter, you need to provide the alias, i.e.:
select count(*)
into nb
from sanctionner s, joueur j
where s.code_joueur = j.code_joueur
and j.num_eq = cart_jaune.code
and s.type_catron like '%jaune%';
In fact, it's best practice to always provide aliases for all columns and binds, especially when embedding SQL within PL/SQL.