Package "set serveroutput on" causing compilation error - oracle

Question

I'm using my class package template to gather two procedures into the package and after pasting and formatting everything, I came up with this error:
This is my package code. It's separated between head and body.
CREATE OR REPLACE
PACKAGE PAQEX AS
PROCEDURE EX3 (P_NOMBRE IN VARCHAR2, P_LUGAR IN VARCHAR2, P_NUMERO IN NUMBER);
PROCEDURE EX2(CPN IN VARCHAR2, NUMER OUT NUMBER );
END PAQEX;
CREATE OR REPLACE
PACKAGE BODY PAQEX AS
PROCEDURE EX3 (P_NOMBRE IN VARCHAR2, P_LUGAR IN VARCHAR2, P_NUMERO IN NUMBER) AS
--
V_AEROPUERTO NUMBER;
V_TERMINAL NUMBER;
V_ID_AEROPUERTO AEROPUERTO.ID%TYPE;
BEGIN
-----------
SELECT COUNT(*) INTO V_AEROPUERTO FROM AEROPUERTO WHERE NOMBRE = P_NOMBRE AND LUGAR = P_LUGAR;
IF V_AEROPUERTO = 0 THEN
INSERT INTO AEROPUERTO (NOMBRE, LUGAR) VALUES (P_NOMBRE, P_LUGAR);
DBMS_OUTPUT.PUT_LINE('INSERTANDO AEROPUERTO');
ELSE
DBMS_OUTPUT.PUT_LINE('YA EXISTE EL AEROPUERTO');
END IF;
SELECT ID INTO V_ID_AEROPUERTO FROM AEROPUERTO WHERE NOMBRE = P_NOMBRE AND LUGAR = P_LUGAR;
------------
SELECT COUNT(*) INTO V_TERMINAL FROM TERMINAL WHERE NUMERO = P_NUMERO AND ID_AEROPUERTO = V_ID_AEROPUERTO;
IF V_TERMINAL = 0 THEN
INSERT INTO TERMINAL (NUMERO, ID_AEROPUERTO) VALUES (P_NUMERO, V_ID_AEROPUERTO);
DBMS_OUTPUT.PUT_LINE('INSERTANDO TERMINAL');
ELSE
DBMS_OUTPUT.PUT_LINE('YA EXISTE LA TERMINAL');
END IF;
END EX3;
PROCEDURE EX2(CPN IN VARCHAR2, NUMER OUT NUMBER ) AS
CURSOR CVUELO IS
SELECT CS.NOMBRE AS COMPA,MDEL.NOMBRE AS MODELL,ASA.NOMBRE AS ORIGEN,AL.NOMBRE AS DESTINO
FROM VUELO VU
INNER JOIN AVION AVI
ON VU.ID_AVION = AVI.ID
INNER JOIN COMPAÑIA CS
ON AVI.ID_COMPAÑIA = CS.ID
INNER JOIN MODELO MDEL
ON AVI.ID_MODELO = MDEL.ID
INNER JOIN PUERTA PS
ON VU.id_puerta_salida = PS.ID
INNER JOIN PUERTA PL
ON VU.id_puerta_llegada = PL.ID
INNER JOIN TERMINAL TS
ON PS.ID_TERMINAL = TS.ID
INNER JOIN TERMINAL TL
ON PL.ID_TERMINAL = TL.ID
INNER JOIN AEROPUERTO ASA
ON TL.ID_AEROPUERTO = ASA.ID
INNER JOIN AEROPUERTO AL
ON TS.ID_AEROPUERTO = AL.ID
WHERE CPN = CS.NOMBRE;
BEGIN
NUMER:=0;
FOR RESULTADO IN CVUELO
LOOP
DBMS_OUTPUT.PUT_LINE(RESULTADO.COMPA || ' | ' || RESULTADO.MODELL ||' | ' ||RESULTADO.ORIGEN||' | ' ||RESULTADO.DESTINO);
NUMER := NUMER + 1;
END LOOP;
DBMS_OUTPUT.PUT_LINE('La compañia ha volado '||numer||' veces');
END EX2;
END PAQEX;
SET SERVEROUTPUT ON;
EXECUTE PAQEX.EX2('AIRBUS',0);
EXECUTE PAQEX.EX3('ADOLFOS','MADRID',3);
I want try each procedure in the package after creating it. They work as stand-alone procedures but not in the package because of that error. Why does it not accept the set serveroutput on command?

Answer 1

There are two ways you could be creating this package; either from a worksheet with all of the code in one script, in which case it should look something like:
CREATE OR REPLACE
PACKAGE PAQEX AS
PROCEDURE EX3 (P_NOMBRE IN VARCHAR2, P_LUGAR IN VARCHAR2, P_NUMERO IN NUMBER);
PROCEDURE EX2(CPN IN VARCHAR2, NUMER OUT NUMBER );
END PAQEX;
/
CREATE OR REPLACE
PACKAGE BODY PAQEX AS
...
END PAQEX;
/
SET SERVEROUTPUT ON;
EXECUTE PAQEX.EX2('AIRBUS',0);
EXECUTE PAQEX.EX3('ADOLFOS','MADRID',3);
with a slash after each PL/SQL object (package specification and package body).
Or you could be creating or modifying the package from the 'New Package...' menu command, and putting the specification and body code into the relevant objects. The schema browser will show "PAQEX" under 'Packages', and if you click that you'll see a tab with the package icon and "PAQEX" containing just:
CREATE OR REPLACE
PACKAGE PAQEX AS
PROCEDURE EX3 (P_NOMBRE IN VARCHAR2, P_LUGAR IN VARCHAR2, P_NUMERO IN NUMBER);
PROCEDURE EX2(CPN IN VARCHAR2, NUMER OUT NUMBER );
END PAQEX;
and a "PAQEX Body" under that; and if you click that you'll see another tab with the package icon and "PAQEX Body" containing just the body code. But you seem to have included code for testing it as part of the body:
PACKAGE BODY PAQEX AS
...
END PAQEX;
SET SERVEROUTPUT ON;
EXECUTE PAQEX.EX2('AIRBUS',0);
EXECUTE PAQEX.EX3('ADOLFOS','MADRID',3);
From the error image you included, you are getting the error you showed when you click the compile icon (cogs).
You need to separate out the test code from the package code. Remove the SET and EXECUTE lines from the package body tab so that just has:
PACKAGE BODY PAQEX AS
...
END PAQEX;
That should then compile, if there are no other errors.
Then to test the package, open an SQL Worksheet (right-click on the connection to see that in the contextual menu) and put in just those three statements:
SET SERVEROUTPUT ON;
EXECUTE PAQEX.EX2('AIRBUS',0);
EXECUTE PAQEX.EX3('ADOLFOS','MADRID',3);
and click 'Run as script' or press F5. (If you click 'Run as statement' or press control-enter then it will only run the command that your cursor is currently in.)
The SQL Developer EXECUTE command is just a wrapper an anonymous block, so you could also combine both calls with:
SET SERVEROUTPUT ON;
BEGIN
PAQEX.EX2('AIRBUS',0);
PAQEX.EX3('ADOLFOS','MADRID',3);
END;
/
You can also test using the 'Run' icon (or pressing control-F10) while looking at the package object editor; it's next to the compile (cogs) icon. That lets you pick a procedure/function from the package and set the argument values.
From the image of the error, you have opened the package body from the object list, it's only showing the boand you are clicking If you're now in the package body editor - not a worksheet - and clicking the compile button to get that error, then remove the SET and EXECUTE commands instead.

Answer 2

Terminate the procedure with a slash:
<snip>
END EX2;
END PAQEX;
/ --> this
SET SERVEROUTPUT ON;
EXECUTE PAQEX.EX2('AIRBUS',0);