How to insert 1000 rows into an Oracle database - oracle

Question

I have this stored procedure:
create or replace procedure InsertProduct
(product_name VARCHAR2,
product_price int,
product_description varchar2)
as
begin
insert into PRODUCT (name, price, description, create_date)
values (product_name, product_price, product_description, sysdate);
end;
I used it to insert 1000 rows at time:
begin
for insert_loop in 1..1000 loop
InsertProduct(dbms_random.string('x', 10), DBMS_RANDOM.value(low => 1, high => 100000) , dbms_random.string('x', 10));
end loop;
commit;
end;
delete from PRODUCT;
but this loop adds random records, is it possible to do so to add real product records, if yes, how to do it?

Answer 1

is it possible to do so to add real product records
Yes, just call your procedure 1000 times with the real data.
For example:
begin
InsertProduct('Apple', 45, 'A red fruit');
InsertProduct('Banana', 33, 'A yellow fruit');
InsertProduct('Cucumber', 70, 'A green vegetable');
InsertProduct('Date', 5, 'A brown fruit');
commit;
end;

Answer 2

Have you looked into using FORALL? If you have the ability to create a collection of records for the data that you want to insert, you can insert them all using one statement similar to the example below.
Using FORALL will also make your code perform faster since it is only 1 INSERT statement with all the records vs 1000 individual INSERT statemements.
DECLARE
TYPE product_t IS TABLE OF product%ROWTYPE;
l_products product_t := product_t();
BEGIN
l_products.extend(3); --number of items we'll be creating
l_products (1).name := 'name1';
l_products (1).price := 1;
l_products (1).description := 'description1';
l_products (2).name := 'name2';
l_products (2).price := 2;
l_products (2).description := 'description2';
l_products (3).name := 'name3';
l_products (3).price := 3;
l_products (3).description := 'description3';
FORALL i IN 1 .. l_products.COUNT
INSERT INTO product (name,
price,
description,
create_date)
VALUES (l_products (i).name,
l_products (i).price,
l_products (i).description,
SYSDATE);
END;
If you want to see how sample data can be created, the example below will create 1500 rows of sample data. Again this will perform faster than the code you provided because it is 1 INSERT vs 1500 INSERTs that it would take using your code.
DECLARE
TYPE product_t IS TABLE OF product%ROWTYPE;
l_products product_t := product_t ();
BEGIN
FOR i IN 1 .. 1500
LOOP
l_products.EXTEND;
l_products (i).name := DBMS_RANDOM.string ('x', 10);
l_products (i).price := DBMS_RANDOM.VALUE (low => 1, high => 100000);
l_products (i).description := DBMS_RANDOM.string ('x', 10);
END LOOP;
FORALL i IN 1 .. l_products.COUNT
INSERT INTO product (name,
price,
description,
create_date)
VALUES (l_products (i).name,
l_products (i).price,
l_products (i).description,
SYSDATE);
END;