awk: search for a string, but only inside a range - bash

Question

I want to search for a string in a file, and print that line plus the line preceding it, but only after the line where string XXX appears in the file. How can I achieve this?
Here is an example: search for lines containing the string "### records", but only after the line that says "start real work"
INPUT FILE
cat << EOF > x.x
start job
initialization
20 records
start real work
first step
30 records
# comments
second step
0 records
#comments
third step
22 records
end
EOF
AWK ONE-LINER - This searches through the whole file, I can't figure out how to only start searching for the string "#### records" after the line that says "start real work"
awk '/records/ && !/^0 records/{for(i=1;i<=x;)print a[i++];print} \
{for(i=1;i<x;i++)a[i]=a[i+1];a[x]=$0;}' x=1 x.x
DESIRED OUTPUT
first step
30 records
third step
22 records

Answer 1

With your shown samples, please try following awk code.
awk '
/start real work/{
found=1
next
}
val && /records/{
if($1>0){
print val ORS $0
}
val=""
next
}
found && NF && !/#/{
val=$0
}
' Input_file
Explanation: Adding detailed explanation for above.
awk ' ##Starting awk program from here.
/start real work/{ ##Check if line contains start real work then do following.
found=1 ##Setting found to 1 here.
next ##next will skip all further statements from here.
}
val && /records/{ ##Checking if val is set and line contains records then do following.
if($1>0){ ##Check if 1st field is greater than 0 then do following.
print val ORS $0 ##printing val ORS and current line here.
}
val="" ##Nullifying val here.
next ##next will skip all further statements from here.
}
found && NF && !/#/{ ##Checking if found is SET and NF is NOT NULL and lines is not having #
val=$0 ##Then set val to current line.
}
' Input_file ##Mentioning Input_file name here.

Answer 2

awk '
/start real work/ { inWork = 1 }
inWork && /^[1-9].* records/ { print prev ORS $0 }
{ prev = $0 }
' file
first step
30 records
third step
22 records

Answer 3

awk '/^start real work/{flag=1} flag && !/[0-9]{2}/{lastline=$0} flag && /^[0-9]{2} records/{print lastline;print}' x.x
first step
30 records
third step
22 records
note:
your problem description does not mention anything about the "step" lines shown your output.
The idea is to set a flag when you see the signal to begin and check the flag along with any other test you may require.
If the flag is set and a line is not a valid "records" line,
then stash it (as lastline).
If the flag is set and the line is a valid two digit "records" line then output the stashed line and then the current line.

Answer 4

With awk in paragraph mode:
awk -v RS= -v FS='\n' -v OFS='\n' '
/start real work/ {f=1;next}
f && (/records/ && !/^#/)
f && (/^#/ && $3 !~ /^0/) {print $2,$3}
' file
first step
30 records
third step
22 records