Applescript cUrl Result and writing one result in a new variable - applescript

Question

I am using applescript and would like to store only a part into a variable from the result of my CURL.
I have the following curl call
set token to (do shell script "curl -X POST
https://api.whatever.test/auth/signin --header 'Content-Type:
application/x-www-form-urlencoded' --data-urlencode
'username=MYUSERNAME' --data-urlencode 'password=MYPASSWORD'
--data-urlencode 'grant_type=password' --data-urlencode 'client_id=myclientid' --data-urlencode
'client_secret=myclientsecret'")
and get the following result:
{
"token_type": "bearer",
"access_token": "d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c",
"expires_in": 3600 }
now i just want to store the tokenvalue in a new variable.
set tokenvalue to ..........?
(here should come in now d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c)
How do I do this?

Answer 1

Unfortunately, it is exactly as I wrote above. I have already tried with set tokenvalue to access_token of token. is there anything I can do to somehow rebuild the result so I can use it?
As you have confirmed in the comments under the OP that the value of token is indeed:
{ "token_type": "bearer", "access_token": "d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c", "expires_in": 3600 }
Not:
{token_type:"bearer", access_token:"d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c", expires_in:3600}
Which is not a valid AppleScript record like what's shown directly above, then using AppleScript's text item delimiters is one way to rework what's returned into something usable.
Note that while in the comments I had you try return word 4 of token I would not rely on or use it and do it in a bit more robust manner, as show in the example AppleScript code below. By doing it this way it provides error handling in that if the value of token does not contain "access_token" then tokenvalue will be missing value and you can test against that for additional error handling. It also allows for "access_token" to be in a different order than shown.
I'd use the following to set the value of tokenvalue to e.g.: d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c
Example AppleScript code:
set AppleScript's text item delimiters to quote
set token to (do shell script "curl -X POST https://api.whatever.test/auth/signin --header 'Content-Type: application/x-www-form-urlencoded' --data-urlencode 'username=MYUSERNAME' --data-urlencode 'password=MYPASSWORD' --data-urlencode 'grant_type=password' --data-urlencode 'client_id=myclientid' --data-urlencode 'client_secret=myclientsecret'")
set AppleScript's text item delimiters to {}
set tokenvalue to missing value
repeat with i from 1 to the length of words of token
if word i of token is "access_token" then
set tokenvalue to word (i + 1) of token
exit repeat
end if
end repeat
return tokenvalue

Answer 2

Updated per comment
You could use sed to extract the desired value. This searches for "access_token": followed by a 40-character alphanumeric.
sed -E 's|.*"access_token": "([[:alnum:]]{40})".*|\1|g'
This is illustrated using the clipboard to simulate your curl result:
set token to do shell script "echo '{ \"token_type\": \"bearer\", \"access_token\": \"d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c\", \"expires_in\": 3600 }'"
--> "{ \"token_type\": \"bearer\", \"access_token\": \"d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c\", \"expires_in\": 3600 }"
set the clipboard to token
--> { "token_type": "bearer", "access_token": "d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c", "expires_in": 3600 }
Then pipe that through sed:
set tokenvalue to do shell script "pbpaste | sed -E 's|.*\"access_token\": \"([[:alnum:]]{40})\".*|\\1|'"
--> "d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c"
You could likely just pipe your curl output through sed but you may need to tweak sed as the shell may automatically strip out some characters (e.g. quotes and spaces).
NB I used [:alnum:] but a-z0-9 would also work.

Answer 3

-- NOTE: uncomment 1st code line and comment 2nd code line to test with CURL
-- set token to (do shell script "curl -X POST https://api.whatever.test/auth/signin --header 'Content-Type: application/x-www-form-urlencoded' --data-urlencode 'username=MYUSERNAME' --data-urlencode 'password=MYPASSWORD' --data-urlencode 'grant_type=password' --data-urlencode 'client_id=myclientid' --data-urlencode 'client_secret=myclientsecret'")
set token to "{ \"token_type\": \"bearer\", \"access_token\": \"d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c\", \"expires_in\": 3600 }"
set tokenvalue to {token_type:"", access_token:"", expires_in:""}
set {ATID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {}}
tell tokenvalue
set its token_type to token's word 2
set its access_token to token's word 4
set its expires_in to (token's word 6) as integer
end tell
set AppleScript's text item delimiters to ATID
return tokenvalue
--> {token_type:"bearer", access_token:"d196a5e5cceb4cf4015693f07e8ea7ce6b19da6c", expires_in:3600}