terraform get values for variables from yaml list - yaml

Question

How can I read the values from the yaml file? I have no more ideas how to do that. This is a super simple example I know, but I still don't get it what the issue is. I need to do this with count not with for_each. The yaml decode part is done by terragrunt.
aws:
-
accounts: "dev"
id: "523134851043"
private_subnets:
eu-central-1a: "10.44.4.96/27"
eu-central-1b: "10.44.5.128/27"
eu-central-1c: "10.44.6.160/27"
-
accounts: "prod"
id: "098453041227"
private_subnets:
eu-central-1a: "10.44.7.0/27"
eu-central-1b: "10.44.8.32/27"
eu-central-1c: "10.44.9.64/27"
variable "aws" {
type = list(object({
accounts: string
id: string
private_subnets: list(object({
cidr: string
}))
}))
}
resource "aws_subnet" "private" {
count = length(var.aws.accounts[*].private_subnets)
availability_zone = element(keys(var.aws.accounts[*].private_subnets), count.index)
cidr_block = element(values(var.aws.accounts[*].private_subnets), count.index)
map_public_ip_on_launch = false
vpc_id = aws_vpc.this.id
It produces this error.
│ Error: Unsupported attribute
│
│ on test.tf line 40, in resource "aws_subnet" "private":
│ 40: count = length(var.aws.accounts[*].private_subnets)
│ ├────────────────
│ │ var.aws is a list of object, known only after apply
│
│ Can't access attributes on a list of objects. Did you mean to access
│ attribute "accounts" for a specific element of the list, or across all
│ elements of the list?
╵
╷
│ Error: Unsupported attribute
│
│ on test.tf line 42, in resource "aws_subnet" "private":
│ 42: availability_zone = element(keys(var.aws.accounts[*].private_subnets), count.index)
│ ├────────────────
│ │ var.aws is a list of object, known only after apply
│
│ Can't access attributes on a list of objects. Did you mean to access
│ attribute "accounts" for a specific element of the list, or across all
│ elements of the list?
╵
╷
│ Error: Unsupported attribute
│
│ on test.tf line 43, in resource "aws_subnet" "private":
│ 43: cidr_block = element(values(var.aws.accounts[*].private_subnets), count.index)
│ ├────────────────
│ │ var.aws is a list of object, known only after apply
│
│ Can't access attributes on a list of objects. Did you mean to access
│ attribute "accounts" for a specific element of the list, or across all
│ elements of the list?
╵
ERRO[0008] 1 error occurred:
* exit status 1

Answer 1

First, the variable type doesn't match your data and code you try to use. It should be:
variable "aws" {
type = list(object({
accounts: string
id: string
private_subnets: map(string)
}))
}
Then I don't understand why you couldn't use for_each. It normally leads code which is easier to understand and maintain, especially when refactoring. count will lead to resource recreations if the order of the data changes.
With for_each you would only need to make sure to use a unique index string, e.g. <az>/<cidr> in this case.
For example:
resource "aws_subnet" "private" {
# Build a map with unique index.
# It might be cleaner to extract this to a local variable.
for_each = merge([
for account in var.aws : {
for az, cidr in account.private_subnets :
"${az}/${cidr}" => { az = az, cidr = cidr }
}
]...)
availability_zone = each.value.az
cidr_block = each.value.cidr
# ...
}
If you really want to use count:
locals {
subnets = flatten([
for account in var.aws : [
for az, cidr in account.private_subnets : { az = az, cidr = cidr }
]
])
}
resource "aws_subnet" "private" {
count = length(local.subnets)
availability_zone = local.subnets[count.index].az
cidr_block = local.subnets[count.index].cidr
# ...
}