Insert line break after every command output in command prompt - windows

Question

I want to save content of every text file in another output text using command prompt. I have used this command:
type ".\test\*.txt" > out.txt
But every output is appended in that text file. How do I introduce line break into output file after every text file read.

Answer 1

Your question is a bit vague so I am guessing you just need to add as many echo's as you need / want.
This is a slight mod on one of the many examples given by forfiles /?
forfiles /p test /m "*.txt" /C "cmd /c type #file >>../out.txt &&echo. >>../out.txt &&echo. >>../out.txt
ensure you rename or delete any existing out.txt before you start

Answer 2

There are several possibilities, which I want to share with you:
Use type to return each file as is, then use findstr /V "$" to find out whether the last line is terminated by a line-break and explicitly output one by echo/ if not, using the conditional execution operator &&:
#echo off
rem // Write to output file:
> "out.txt" (
rem // Loop through input files to resolve wildcards:
for %%F in (".\test\*.txt") do (
rem // First type out the currently iterated file:
type "%%~F"
rem /* Let `findstr` detect whether there is a terminating line-break,
rem and conditionally append one if not: */
> nul findstr /V /M "$" "%%~F" && echo/
)
)
Caveats:
files must be less than 2 GiB in size?
Use find /V "", which appends a line-break to the last line if not present. Since find usually outputs a header that we do not need, provide the files via input redirection < rather than as arguments. Since redirection does not support wildcards, let a standard for-loop resolve them:
#echo off
rem // Write to output file:
> "out.txt" (
rem // Loop through input files since `<` does not support wildcards:
for %%F in (".\test\*.txt") do (
rem // Let `find` return all lines with a terminating line-break:
< "%%~F" find /V ""
)
)
Caveats:
files must be less than 2 GiB in size?
lines must be shorter than 4 KiB;
Use more /V "", which appends a line-break to the last line if not present. To avoid a prompt after each file, let a for-loop resolve wildcards rather than more:
#echo off
rem // Write to output file:
> "out.txt" (
rem // Loop through input files since `more` awaits prompt per file on wildcards:
for %%F in (".\test\*.txt") do (
rem // Let `more` return all lines with a terminating line-break:
more "%%~F"
)
)
Caveats:
files must be less than 2 GiB in size?
files must contain less than 64 Ki lines;
lines must be shorter than 64 KiB;
TABs become expanded to SPACEs;
Use sort, which appends a line-break to the last line if not present. To avoid resorting of the lines, specify the character start position for sorting beyond the supported line length. Since sort then reverses the entire file, simply apply the command twice:
#echo off
rem // Write to output file:
> "out.txt" (
rem // Loop through input files to not unintentionally rearrange lines:
for %%F in (".\test\*.txt") do (
rem // Let `sort` return all lines with a terminating line-break:
sort "%%~F" /+65535 /REC 65535 | sort /+65535 /REC 65535
)
)
Caveats:
files must be less than 2 GiB in size?
lines must be shorter than 64 KiB;
Read each file by for /F and echo out each line, so each one, even the last one, will be terminated by a line-break; findstr is there to precede each line with its line number plus a colon in order for them not to appear empty to for /F, which would skip such lines; the prefix becomes then stripped off in the loop body:
#echo off
rem // Write to output file:
> "out.txt" (
rem // Loop through input files since `for /F` does not support wildcards:
for %%F in (".\test\*.txt") do (
rem // Precede each line by line number plus `:`, then read each augmented line:
for /F "delims=" %%L in ('findstr /N "^" "%%~F"') do (
rem // Store currently read augmented line:
set "LINE=%%L"
rem // Toggle delayed expansion to aviod loss of `!`:
setlocal EnableDelayedExpansion
rem // Remove line number prefix and return current line with a line-break:
echo(!LINE:*:=!
endlocal
)
)
)
Caveats:
files must be less than 2 GiB in size;
lines must be shorter than about 8 KiB;