Highlight word in TListView Delphi 7 - delphi-7

Question

I'm trying to highlight a word from TListView but I can't make it work. My first attempt is to highlight the first letter of each row but won't work. TListView won't display anything. Here is my code:
procedure TfrmMain.lvMainDrawItem(Sender: TCustomListView; Item: TListItem; Rect: TRect; State: TOwnerDrawState);
var
r : TRect;
c : TCanvas;
begin
r := Item.DisplayRect(drBounds);
c := Sender.Canvas;
c.Brush.Color := clWindow;
c.Font.Color := clWindowText;
c.TextRect(r, 1, 1, 'a');
end;
I based my code here but it is written in XE10.4. I'm using delphi 7. How can I highlight word/first letter of each row in TListView?

Answer 1

You are drawing outside of the item's bounding rectangle, that is why you don't see anything. The X,Y coordinates you specify to TextRect() are relative to the top/left corner of the ListView's client area, but are clipped by the specified TRect.
Try this instead:
c.TextRect(r, r.Left+1, r.Top+1, 'a');

Answer 2

Here is my working code:
set and populate list view
procedure TForm1.Button1Click(Sender: TObject);
begin
ListView1.Clear;
ListView1.ViewStyle := vsReport;
ListView1.RowSelect := True;
ListView1.Items.Add.Caption := 'banana';
ListView1.Items.Add.Caption := 'apple and banana';
ListView1.Items.Add.Caption := 'orange apple and banana';
ListView1.Items.Add.Caption := 'banana and orange';
ListView1.Items.Add.Caption := 'banana orange and apple';
ListView1.Items.Add.Caption := 'appleXandXbanana';
ListView1.Items.Add.Caption := 'orangeXappleXand banana';
ListView1.Items.Add.Caption := 'bananaXandXorange';
ListView1.Items.Add.Caption := 'bananaXorangeXandXapple';
end;
painting
procedure TForm1.ListView1DrawItem(Sender: TCustomListView;Item: TListItem; Rect: TRect; State: TOwnerDrawState);
var
r : TRect;
c : TCanvas;
sText : string;
sTemp : string;
nPos : Integer;
nLen : Integer;
lv : TListView;
begin
if item = nil then
begin
Exit;
end;
r := Item.DisplayRect(drBounds);
c := Sender.Canvas;
lv := TListView(Sender);
// fKeyword := 'apple';
sText := Item.Caption;
nLen := Length(fKeyword);
nPos := AnsiPos(fKeyword, sText);
// first part : before match
sTemp := Copy(sText, 1, nPos - 1);
if sTemp <> '' then
begin
c.Brush.Color := clWindow;
c.Font.Color := clWindowText;
c.TextRect(r, r.Left, r.Top, sTemp);
Inc(r.Left, c.TextWidth(sTemp));
end;
// second part: match
sTemp := Copy(sText, nPos, nLen);
if (nPos > 0) and (sTemp <> '') then
begin
c.Brush.Color := clRed;
c.Font.Color := clBlue;
c.TextRect(r, r.Left + 1, r.Top, sTemp);
Inc(r.Left, c.TextWidth(sTemp));
end;
// third part : after match
if nPos = 0 then
begin
sTemp := sText;
end
else
begin
sTemp := Copy(sText, nPos + nLen, Length(sText) - nPos - nLen + 1);
end;
c.Brush.Color := clWindow;
c.Font.Color := clWindowText;
c.TextRect(r, r.Left + 1, r.Top, sTemp);
Inc(r.Left, c.TextWidth(sTemp));
if odFocused in State then
begin
lv.Canvas.Brush.Style := bsSolid;
lv.Canvas.Brush.Color := clBlack;
lv.Canvas.Font.Color := clWhite;
DrawFocusRect(lv.Canvas.Handle, Rect);
end;
end;