CLIPSjni integrated JADE java - clips

Question

I just started working with CLIPS integrated with Jade one agent.java, I have my facts and rules loaded in different .clp files, I already spent a lot of time trying to compare what I think are numbers but for some reason it doesn´t work, tried many different things nothing make it works:
Here part of my facts:
(deffacts products
(product (name "USB Memory") (category storage) (part-number 1234) (price 9.99))
(product (name Amplifier) (category electronics) (part-number 2341) (price 399.99))
(product (name Speakers) (category electronics) (part-number 23241) (price 19.99))
(product (name "iPhone 7") (category smartphone) (part-number 3412) (price 99))
(product (name "Samsung Edge 7") (category smartphone) (part-number 34412) (price 88))
)
And here I have the rules that are not working:
(defrule my-rule14
(not (product (category smartphone) **(price<50)**))
=>
(printout t "no smartphones cheaper than 50" crlf ))
;; Defining a rule for finding smartphones cheaper than 100 dlls
(defrule my-rule15
(product (category smartphone) (name ?nameb) **(price<100))**
=>
(printout t ?nameb " is cheaper than 100 dlls" crlf ))
None of the rules are working I tried changing comparison to {price<100}, (price< 100), (price < 100), (price ?pricea) (test(< ?pricea 100))
Thanks.

Answer 1

Sections 5.4.1.5 and 5.4.2 of the Basic Programming Guide contain the relevant information for the syntax needed:
CLIPS (6.4 2/9/21)
CLIPS>
(deftemplate product
(slot name)
(slot category)
(slot part-number)
(slot price))
CLIPS>
(deffacts products
(product (name "USB Memory") (category storage) (part-number 1234) (price 9.99))
(product (name Amplifier) (category electronics) (part-number 2341) (price 399.99))
(product (name Speakers) (category electronics) (part-number 23241) (price 19.99))
(product (name "iPhone 7") (category smartphone) (part-number 3412) (price 99))
(product (name "Samsung Edge 7") (category smartphone) (part-number 34412) (price 88)))
CLIPS>
(defrule my-rule14
(not (product (category smartphone) (price ?price&:(< ?price 50))))
=>
(printout t "no smartphones cheaper than 50" crlf))
CLIPS>
(defrule my-rule15
(product (category smartphone) (name ?nameb) (price ?price))
(test (< ?price 100))
=>
(printout t ?nameb " is cheaper than 100 dlls" crlf ))
CLIPS> (reset)
CLIPS> (agenda)
0 my-rule15: f-5
0 my-rule15: f-4
0 my-rule14: *
For a total of 3 activations.
CLIPS> (run)
Samsung Edge 7 is cheaper than 100 dlls
iPhone 7 is cheaper than 100 dlls
no smartphones cheaper than 50
CLIPS>