Echo Information One Line Under FINDSTR Result - windows

Question

I am not sure if this is easily possible. I can easily parse any line that contains the same information. If I wanted to find all the lines that contain billing info in test.txt I could do findstr /c:"Billing" test.txt
But what if I wanted the line after the findstr result. In this example I would like to try and find the user notes but they are on the line below.
Edit:
The random strings are exactly that. They contain no similar characters. Also the actual file contains hundreds of lines not only the four I have included as an example.
Billing Info 1234
PayPal Manage Payment
User Notes:
ABC RANDOM STRING
Billing Info 5678
PayPal Manage Payment
User Notes:
DEF RANDOM STRING
Billing Info qwerty
PayPal Manage Payment
User Notes:
XYZ RANDOM STRING
I thought something could be done with a for loop and the skip flag.
for /f "skip=1 tokens=1*" %a in ('findstr /c:"User" test.txt') do (echo %a %b)
But I think skip skips lines at the start of file rather than at each result.
Apologies if this is painfully obvious, thank you for any help or advice.
Rory

Answer 1

FINDSTR cannot be used here as it always processes a text file line by line. It is not possible to search for a line below another line or instruct FINDSTR to output additional lines below or above a line containing a found string.
The following batch file code may work:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
if not exist "test.txt" exit /B 1
set "UserNotes="
for /F usebackq^ delims^=^ eol^= %%# in ("test.txt") do for /F tokens^=1^,2^ eol^= %%I in ("%%#") do (
if "%%I %%J" == "Billing Info" (
set "UserNotes="
) else if "%%I %%J" == "User Notes:" (
set "UserNotes=1"
) else if defined UserNotes (
echo(%%#
)
)
endlocal
The outer FOR /F loop processes the text file with ignoring only empty lines. Each non-empty line is assigned as is to the specified loop variable # because of the definition of an empty list of delimiters and no end of line character. The syntax without usage of surrounding " must be used here as this is the only possibility to specify no delimiter and no end of line character.
The inner FOR /F loop processes the current line by splitting the line up into substrings (tokens) with using normal space and horizontal tab as string delimiters. The end of line character is again defined with no character as the user note to output could start also with a semicolon after zero or more leading spaces/tabs which should not be ignored by the inner FOR /F loop. Just the first two space/tab separated strings are of interest and are assigned therefore to the loop variables I and J.
The first IF condition is true on current line starting with the two words which indicate that a new data block begins which means the user notes section of previous data block ends. The environment variable UserNotes is deleted in this case.
The second IF condition is true on current line starting with the two words which indicate that next the user notes follow. For that reason the environment variable UserNotes is defined with a value. The value itself does not matter.
The third IF condition is true only if the other two IF conditions are false and the environment variable UserNotes is defined at the moment. In this case a non-empty line with user notes is currently assigned by the outer FOR /F to the loop variable # which is output now (or further processed).
There is used echo(%%# instead of echo %%# to output correct also a user note line which contains only spaces/tabs and nothing else (blank but not empty line). The usage of echo %%# would result in this case in output of current state of the command echo mode. The usage of ( as delimiter between the command ECHO and the non-empty line to output prevents the output of the state of the command echo mode on blank line to output.
The following batch file can be used if all user notes should be written into a text file like UserNotes.txt in current directory.
#echo off
setlocal EnableExtensions DisableDelayedExpansion
if not exist "test.txt" exit /B 1
set "UserNotes="
(for /F usebackq^ delims^=^ eol^= %%# in ("test.txt") do for /F tokens^=1^,2^ eol^= %%I in ("%%#") do (
if "%%I %%J" == "Billing Info" (
set "UserNotes="
) else if "%%I %%J" == "User Notes:" (
set "UserNotes=1"
) else if defined UserNotes (
echo(%%#
)
))>"UserNotes.txt"
if exist "UserNotes.txt" for %%I in ("UserNotes.txt") do if %%~zI == 0 del "UserNotes.txt"
endlocal
The file UserNotes.txt is deleted on being created before, but nothing is output into this file.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
del /?
echo /?
endlocal /?
exit /?
findstr /?
for /?
if /?
set /?
setlocal /?