I'm getting a 'Procedure created with compilation errors.' - oracle

Question

I'm a beginner to sql and i'm getting a compilation error, can anyone pls guide me with my mistake in the code.
set serveroutput on;
create or replace procedure p1(n in varchar) as
cursor c1 is
select e_name, inv_amount
from employee, investment
where employee.e_id=investment.e_id
and inv_amount=50000;
c c1 %rowtype;
begin
open c1;
dbms_output.put_line('e_name'||"||'inv_amount');
loop
fetch c1 into c;
exit when c1 %notfound;
if(c.inv_amount=n)then
dbms_output.put_line(c.e_name||c.inv_amount);
end if;
end loop;
close c1;
end;
/

Answer 1

I can see some potential errors in your code. Which must be fixed as -
set serveroutput on;
create or replace procedure p1(n in varchar)
AS
cursor c1 is
select e_name,inv_amount
from employee,investment
where employee.e_id=investment.e_id
and inv_amount=50000;
c c1%rowtype; -- No space between cursor and ROWTYPE keyword
begin
open c1;
dbms_output.put_line('e_name'||''||'inv_amount'); -- It must be 2 single quotes instead of 1 double quotes
loop
fetch c1 into c;
exit when c1%notfound; -- Remove space
if(c.inv_amount=n)then
dbms_output.put_line(c.e_name||c.inv_amount);
end if;
end loop;
close c1;
end;
/

Answer 2

You can simplify this quite a lot:
You only care about rows where inv_amount = n, so why not add that as a filter condition in the cursor.
The Cursor FOR loop construction avoids the need to declare everything explicitly.
create or replace procedure p1
( n in number )
as
begin
for r in (
select e_name, inv_amount
from employee e
join investment i on i.e_id = e.e_id
where inv_amount = n
)
loop
dbms_output.put_line(r.e_name || ': ' || r.inv_amount);
end loop;
end p1;
It's also best to write joins using the join keyword.
Note that SQL is the query language and PL/SQL is the programming language, so this a PL/SQL procedure, not SQL.
Regarding "Procedure created with compilation errors", you need to get familiar with how to display and trace compilation errors using your development tool. In SQL*Plus, type
show errors
and you'll get something like this (using your original version of the procedure):
Warning: Procedure created with compilation errors.
SQL> show errors
Errors for PROCEDURE P1:
LINE/COL ERROR
---------- ---------------------------------------------------------------------------------------------------
10/34 PLS-00112: end-of-line in quoted identifier
10/35 PLS-00103: Encountered the symbol "||'inv_amount');" when expecting one of the following:
( - + case mod new null <an identifier>
<a double-quoted delimited-identifier> <a bind variable>
continue avg count current max min prior sql stddev sum
variance execute forall merge standard time timestamp
interval date
<a string literal with character set specification>
<a number> <a single-quoted SQL string> pipe
<an alternatively-quoted string literal with character set specification>
<
You can use the list command to print individual lines, for example line 10 mentioned in the compilation error:
SQL> l 10
10* dbms_output.put_line('e_name'||"||'inv_amount');
or list a range, e.g. lines 8-11:
SQL> l 8 11
8 begin
9 open c1;
10 dbms_output.put_line('e_name'||"||'inv_amount');
11* loop
If you are not using SQL*Plus, you can always query the user_errors dictionary view. However, developer tools like SQL Developer, PL/SQL Developer and Toad highlight compilation errors right in the editor so no special commands are needed.