Slicing vector of matrices - matrix

Question

I would like to slice a vector of matrices by some condition. The code I have now looks like
sliced = data[:][[data[:][end,1] .> 0]
where data is a vector of irregularly sized matrices of size (n,2). The above code doesn't work, because it thinks I'm trying to slice the last element of the vector or something. The overall question I'm trying to ask is whether there is a way to slice an irregular vector of matrices based on some consistent condition?

Answer 1

(Edited based on the clarification of the condition, thanks to #DanGetz)
Given a data vector of matrices:
julia> data = [[1 2; 3 4; 5 6; 7 8], [-1 -2], [10 20; 30 40], [9 8; -7 6]]
4-element Vector{Matrix{Int64}}:
[1 2; 3 4; 5 6; 7 8]
[-1 -2]
[10 20; 30 40]
[9 8; -7 6]
If we wanted to use logical indexing like in the question, we could broadcasting on an anonymous function like so:
julia> data[(m -> m[end, begin] > 0).(data)]
2-element Vector{Matrix{Int64}}:
[1 2; 3 4; 5 6; 7 8]
[10 20; 30 40]
But in this case, an array comprehension or a filter would be clearer:
julia> [m for m in data if m[end, begin] > 0]
2-element Vector{Matrix{Int64}}:
[1 2; 3 4; 5 6; 7 8]
[10 20; 30 40]
julia> filter(data) do (m)
m[end, begin] > 0
end
2-element Vector{Matrix{Int64}}:
[1 2; 3 4; 5 6; 7 8]
[10 20; 30 40]
(begin here is a generic way of writing the first index of an array dimension - it works both for normal arrays where the first index is 1, and for things like OffsetArrays.)