How select nodes combining preceding-sibling and following sibling? - xpath

Question

I want to select all nodes preceding-sibling A and following-sibling A, excluding following-sibling C and D
XML :
<XMLCODE>
<ex>
<z>bla</z>
<z>bla</z>
<A/>
<k>want</k>
<b>want</b>
<A/>
<b>bla</b>
<h>bla</h>
<C/>
<z>bla</z>
<D/>
<e>bla</e>
<A/>
<j>want</j>
<A/>
<i>bla</i>
<C/>
<y>bla</y>
<C/>
<y>bla</y>
</ex>
</XMLCODE>
output:
<k>want</k>
<b>want</b>
<j>want</j>
I tried
//*[
preceding-sibling::*[self::A ]
and
following-sibling::*[self::A ]
]
[not(self::A)]
Thanks

Answer 1

This is how I would approach this:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:key name="trail" match="*[not(self::A)]" use="generate-id(preceding-sibling::A[1])" />
<xsl:template match="/XMLCODE">
<result>
<xsl:for-each select="ex/A[position() mod 2 = 1]">
<xsl:copy-of select="key('trail', generate-id())"/>
</xsl:for-each>
</result>
</xsl:template>
</xsl:stylesheet>
Applied to your input example, this will return:
Result
<?xml version="1.0" encoding="UTF-8"?>
<result>
<k>want</k>
<b>want</b>
<j>want</j>
</result>
This is actually an XSLT 1.0 method. In XSLT 2.0 you could ostensibly do something with:
<xsl:for-each-group select="ex/*" group-starting-with="A">
but I don't see an elegant method to distinguish between the "on" and "off" groups, since the first group could start with an A or not.

Answer 2

Use this XPath 1.0 expression:
/*/ex/*[not(self::A or self::B or self::C)
and
(
preceding-sibling::A[1] | preceding-sibling::B[1] | preceding-sibling::C[1]
)[last()][self::A]
and
(
following-sibling::A[1] | following-sibling::B[1] | following-sibling::C[1]
)[1][self::A]
]
XSLT - based verification:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/">
<xsl:copy-of select=
"/*/ex/*[
not(self::A or self::B or self::C)
and
(
preceding-sibling::A[1] | preceding-sibling::B[1] | preceding-sibling::C[1]
)[last()][self::A]
and
(
following-sibling::A[1] | following-sibling::B[1] | following-sibling::C[1]
)[1][self::A]
]"/>
</xsl:template>
</xsl:stylesheet>
When this transformation is applied on the provided XML document:
<XMLCODE>
<ex>
<z>bla</z>
<z>bla</z>
<A/>
<k>want</k>
<b>want</b>
<A/>
<b>bla</b>
<h>bla</h>
<C/>
<z>bla</z>
<D/>
<e>bla</e>
<A/>
<j>want</j>
<A/>
<i>bla</i>
<C/>
<y>bla</y>
<C/>
<y>bla</y>
</ex>
</XMLCODE>
The Xpath expression is evaluated and the results of this are copied to the output --the correct, wanted result is produced:
<k>want</k>
<b>want</b>
<j>want</j>

Answer 3

I think you can do
let $A := //A
return for-each-pair(
$A[position() mod 2 = 1],
$A[position() mod 2 = 0],
function($A1, $A2) {
$A1/following-sibling::* intersect $A2/preceding-sibling::*
}
)
XPath 3.1 with higher-order function support but Saxon 10 and later in all editions, SaxonJS 2 and Saxon 9.8/9.9 PE/EE do that.

Answer 4

Using xslt-1.0 and exslt to extract element nodes between pairs of A elements:
xmlstarlet select -t \
-m '*/*/A[following-sibling::A][count(preceding-sibling::A) mod 2 = 0]' \
-c 'set:leading(following-sibling::*,following-sibling::A[1])' \
file.xml
-m iterates over A element pairs, changing the context to the first A
-c copies following sibling elements up to, and excluding, the second A
set:leading documentation on github.io,
implementation on github.com.
Output:
<k>want</k><b>want</b><j>want</j>
To have xmlstarlet select list the generated XSLT add a -C
option before -t:
<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:exslt="http://exslt.org/common" xmlns:set="http://exslt.org/sets" version="1.0" extension-element-prefixes="exslt set">
<xsl:output omit-xml-declaration="yes" indent="no"/>
<xsl:template match="/">
<xsl:for-each select="*/*/A[following-sibling::A][count(preceding-sibling::A) mod 2 = 0]">
<xsl:copy-of select="set:leading(following-sibling::*,following-sibling::A[1])"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>