Unique random numbers series in fortran - random

Question

I have this problem in Fortran where I need to generate a sequence of random numbers (precisely, 729 random numbers between 1 and 1000) and to do I use the intrinsic function random_number().
The problem, of course, is that it returns pseudorandom numbers and it happens to often that I get same values repeated. I'm not an expert in programming with Fortran, but how can I get 729 unique random numbers without repetitions? Can someone help me?

Answer 1

Here you go
ijb#LAPTOP-GUG8KQ9I:~/work/stack$ cat the_chosen.f90
Program possibly_homework
Use, Intrinsic :: iso_fortran_env, Only : wp => real64
Implicit None( Type, External )
Integer, Parameter :: from = 1000
Integer, Parameter :: to_choose = 729
Real( wp ) :: rand
Integer, Dimension( : ), Allocatable :: the_many
Integer, Dimension( : ), Allocatable :: the_chosen
Integer :: the_chosen_one
Integer :: unit
Integer :: i
Allocate( the_many( 1:from ) )
the_many = [ ( i, i = 1, from ) ]
Allocate( the_chosen( 1:0 ) )
Do i = 1, to_choose
Call Random_number( rand )
the_chosen_one = 1 + Int( Size( the_many ) * rand )
the_chosen = [ the_chosen, the_many( the_chosen_one ) ]
the_many = [ the_many( :the_chosen_one - 1 ), the_many( the_chosen_one + 1: ) ]
End Do
Open( newunit = unit, file = 'the_chosen.dat' )
Do i = 1, Size( the_chosen )
Write( unit, '( i0, t20, i0 )' ) i, the_chosen( i )
End Do
Close( unit )
End Program possibly_homework
ijb#LAPTOP-GUG8KQ9I:~/work/stack$ gfortran --version
GNU Fortran (Ubuntu 9.4.0-1ubuntu1~20.04.1) 9.4.0
Copyright (C) 2019 Free Software Foundation, Inc.
This is free software; see the source for copying conditions. There is NO
warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
ijb#LAPTOP-GUG8KQ9I:~/work/stack$ gfortran -std=f2018 -Wall -Wextra -fcheck=all -O -g the_chosen.f90 -o the_chosen
ijb#LAPTOP-GUG8KQ9I:~/work/stack$ ./the_chosen
ijb#LAPTOP-GUG8KQ9I:~/work/stack$ head the_chosen.dat
1 303
2 916
3 414
4 452
5 116
6 962
7 392
8 675
9 153
10 458
ijb#LAPTOP-GUG8KQ9I:~/work/stack$ sort +1 -n the_chosen.dat | awk '{ print $2 }' | uniq -D
ijb#LAPTOP-GUG8KQ9I:~/work/stack$

Answer 2

This shows how you can in an inelegant way solve your problem.
program p
implicit none
integer, parameter :: n = 10
logical :: a(n) = .false.
integer b(n), cnt
real x
cnt = 1
do
call random_number(x)
b(cnt) = n * x + 1
if (.not. a(b(cnt))) then
if (b(cnt) > n) cycle
a(b(cnt)) = .true.
cnt = cnt + 1
if (cnt > n) exit
end if
end do
print '(*(1X,I0))', b
end program p

Answer 3

Order not important (as per Marta's question at How to remove random rows from a matrix in Fortran90 ). No shuffle required.
program test
implicit none
integer Nmax, Nsample, Nchoose
logical start
logical, allocatable :: mask(:)
integer cnt, i
real r
Nmax = 10 ! or 1000
Nsample = 7 ! or 729
start = .false.
Nchoose = Nsample
if ( Nsample > Nmax / 2 ) then
start = .true. ! go for the SMALLER likelihood of already taken
Nchoose = Nmax - Nsample
end if
allocate ( mask(Nmax) )
mask = start
cnt = 0
call random_seed()
do while ( cnt < Nchoose )
call random_number( r )
i = 1 + r * Nmax
if ( mask(i) .eqv. start ) then
mask(i) = .not. mask(i)
cnt = cnt + 1
end if
end do
do i = 1, Nmax
if ( mask(i) ) write( *, * ) i
end do
end program test