Merge many tab seprated files based on first column - bash

Question

I have many TSV files in a directory that have only three columns, I want to merge all of them based on the first column value (both columns have headers that I need to maintain); if this value is present then it must add the value of the corresponding second and third column, and if value missing in any file add NA and so on (see example). Files might have different number of lines and not ordered by first column, although this can be easily done with sort.
I have tried join but that works nicely for only two files. Can join be expanded for all files in a directory? Here are the example of just three files:
S01.tsv
Accesion Val S01
AJ863320 1 0.2
AM930424 1 0.3
AY664038 2 0.5
S02.tsv
Accesion Val S02
AJ863320 2 0.8
AM930424 1 0.25
EU236327 1 0.14
EU434346 2 0.2
S03.tsv
Accesion Val S03
AJ863320 5 0.2
EU236327 1 0.5
EU434346 2 0.3
Outfile should be:
Accesion Val S01 S02 S03
AJ863320 1 0.2 NA NA
AJ863320 2 NA 0.8 NA
AJ863320 5 NA NA 0.2
AM930424 1 0.3 0.25 NA
AY664038 2 0.5 NA NA
EU236327 1 NA 0.14 0.5
EU434346 2 NA 0.2 0.3
Ok I've tried with awk by taking help here, but not successful
BEGIN { OFS="\t" } # tab separated columns
FNR==1 { f++ } # counter of files
{
a[0][$1]=$1 # reset the key for every record
for(i=2;i<=NF;i++) # for each non-key element
a[f][$1]=a[f][$1] $i ( i==NF?"":OFS ) # combine them to array element
}
END { # in the end
for(i in a[0]) # go thru every key
for(j=0;j<=f;j++) # and all related array elements
printf "%s%s", a[j][i], (j==f?ORS:OFS)
} # output them, nonexistent will output empty

Answer 1

I would harness GNU AWK for this task following way, let S01.tsv content be
Accesion Val S01
AJ863320 1 0.2
AM930424 1 0.3
AY664038 2 0.5
and S02.tsv content be
Accesion Val S02
AJ863320 2 0.8
AM930424 1 0.25
EU236327 1 0.14
EU434346 2 0.2
and S03.tsv content be
Accesion Val S03
AJ863320 5 0.2
EU236327 1 0.5
EU434346 2 0.3
then
awk 'BEGIN{OFS="\t"}NR==1{title=$1 OFS $2}{arr[$1 OFS $2][FILENAME]=$3}END{print title,arr[title]["S01.tsv"],arr[title]["S02.tsv"],arr[title]["S03.tsv"];delete arr[title];for(i in arr){print i,"S01.tsv" in arr[i]?arr[i]["S01.tsv"]:"NA","S02.tsv" in arr[i]?arr[i]["S02.tsv"]:"NA","S03.tsv" in arr[i]?arr[i]["S03.tsv"]:"NA"}}' S01.tsv S02.tsv S03.tsv
gives output
Accesion Val S01 S02 S03
AJ863320 1 0.2 NA NA
AJ863320 2 NA 0.8 NA
AJ863320 5 NA NA 0.2
EU236327 1 NA 0.14 0.5
AM930424 1 0.3 0.25 NA
EU434346 2 NA 0.2 0.3
AY664038 2 0.5 NA NA
Explanation: I am storing data in 2D array arr, using values from 1st and 2nd column concatenated using output field separator (first dimension) and filename (2nd dimensions). Values in array are values from 3rd column. After data is collected I started by printing title (header) row, which I then delete from array, then I iterate over first dimension of array, and for each element I print key followed by values from each file or NA if there was not value. Observe that I use in check rather than looking for truthiness of value itself as this would alter 0 values into NAs. Disclaimer: this solution assumes you are accepting any order of output rows beyond headers, if this does not hold do not use this solution.
(tested in GNU Awk 5.0.1)

Answer 2

Using GNU awk for arrays of arrays and sorted_in:
$ cat tst.awk
BEGIN { FS=OFS="\t" }
FNR == 1 {
if ( NR == 1 ) {
numCols = split($0,hdrs)
}
else {
hdrs[++numCols] = $3
}
next
}
{
accsValsCols2ss[$1][$2][numCols] = $3
}
END {
for ( colNr=1; colNr<=numCols; colNr++ ) {
printf "%s%s", hdrs[colNr], (colNr<numCols ? OFS : ORS)
}
PROCINFO["sorted_in"] = "#ind_str_asc"
for ( acc in accsValsCols2ss ) {
PROCINFO["sorted_in"] = "#ind_num_asc"
for ( val in accsValsCols2ss[acc] ) {
printf "%s%s%s", acc, OFS, val
for ( colNr=3; colNr<=numCols; colNr++ ) {
s = ( colNr in accsValsCols2ss[acc][val] ? accsValsCols2ss[acc][val][colNr] : "NA" )
printf "%s%s", OFS, s
}
print ""
}
}
}
$ awk -f tst.awk S01.tsv S02.tsv S03.tsv
Accesion Val S01 S02 S03
AJ863320 1 0.2 NA NA
AJ863320 2 NA 0.8 NA
AJ863320 5 NA NA 0.2
AM930424 1 0.3 0.25 NA
AY664038 2 0.5 NA NA
EU236327 1 NA 0.14 0.5
EU434346 2 NA 0.2 0.3