Add Buffer to ByteArray - delphi-7

Question

I use winsock to receive a 1024byte buffer like this:
var
buffer : array[0..1023] of byte;
endarray : array of byte;
hFile : THandle;
dwWritten : DWORD;
dwRead : DWORD;
begin
SetLength (endarray, 3000); //fixxed size (doesn't really matter here, cause I know the size)
hFile := CreateFileW('test.bin', GENERIC_WRITE, FILE_SHARE_WRITE, nil, CREATE_NEW, 0, 0);
SetFilePointer(hFile, 0, nil, FILE_BEGIN);
repeat
dwRead := recv(MySock, Buffer, 1024, 0);
WriteFile(hFile, buffer[0], dwRead, dwWritten, nil); // works fine!
// Add the buffer to the endarray but how?
until (dwRead = 0) or (dwRead = -1)
[...]
CloseHandle (hFile);
end;
How can I add the buffer to the endarray automatically so it actually gets appended to the end?

Answer 1

Like this:
var
PrevLen: Integer;
....
dwRead := recv(MySock, Buffer, 1024, 0);
if dwRead>0 then
begin
PrevLen := Length(endarray);
SetLength(endarray, PrevLen+dwRead);
Move(Buffer[0], endarray[PrevLen], dwRead);
end;
And also remove the first line of code from your function that pre-allocates endarray.
If you'd rather allocate the buffer once (as per the code in the question) then you can code it like this:
var
endarrayLen: Integer;
.....
endarrayLen := 0;
repeat
dwRead := recv(MySock, Buffer, 1024, 0);
if dwRead>0 then
begin
Move(Buffer[0], endarray[endarrayLen], dwRead);
inc(endarrayLen, dwRead);
end;
.....
until ...
But that's a buffer overrun waiting to happen!

Answer 2

You can use the TMemoryStream or TBytesStream class. Both represent a dynamically-growable block of memory. TMemoryStream operates on a raw memory block, whereas TBytesStream operates on a dynamic array of bytes. For example:
var
buffer : array[0..1023] of byte;
endarray : TMemoryStream;
hFile : THandle;
iRead : Integer;
dwWritten : DWORD;
begin
endarray := TMemoryStream.Create;
try
hFile := CreateFileW('test.bin', GENERIC_WRITE, FILE_SHARE_WRITE, nil, CREATE_NEW, 0, 0);
try
repeat
iRead := recv(MySock, buffer, sizeof(buffer), 0);
if iRead < 1 then Break;
WriteFile(hFile, buffer[0], iRead, dwWritten, nil);
endarray.WriteBuffer(buffer[0], iRead);
until False;
[...]
finally
CloseHandle (hFile);
end;
// use endarray.Memory as needed, up to endarray.Size number of bytes ...
finally
endarray.Free;
end;
end;
.
var
buffer : array[0..1023] of byte;
endarray : TBytesStream;
hFile : THandle;
iRead : Integer;
dwWritten : DWORD;
begin
endarray := TBytesStream.Create(nil);
try
hFile := CreateFileW('test.bin', GENERIC_WRITE, FILE_SHARE_WRITE, nil, CREATE_NEW, 0, 0);
try
repeat
iRead := recv(MySock, buffer, sizeof(buffer), 0);
if iRead < 1 then Break;
WriteFile(hFile, buffer[0], iRead, dwWritten, nil);
endarray.WriteBuffer(buffer[0], iRead);
until False;
[...]
finally
CloseHandle (hFile);
end;
// use endarray.Bytes as needed, up to endarray.Size number of bytes ...
finally
endarray.Free;
end;
end;