OS file from BLOB in Oracle - oracle

Question

I'm thinking about is it whether possible to write Oracle blobs to OS files. On first glance it is possible only using external procedures but may be something changed....
How to save a BLOB to a file on disk in PL/SQL From: Thomas Kyte
Use DBMS_LOB to read from the BLOB
You will need to create an external procedure to take binary data and
write it to the operating system, the external procedure can be
written in C. If it was CLOB data, you can use UTL_FILE to write it to
the OS but UTL_FILE does not support the binary in a BLOB.

Answer 1

Migrations of files from table to OS files de SO, using DB Job
Example base on table fou_archvos, it has files on column "archivo", id+nombre will be concatenated.
SQL> desc fou_archvos
Name Null? Type
----------------------------------------- -------- ----------------------------
ID NOT NULL NUMBER
NOMBRE NOT NULL VARCHAR2(300)
ACTIVO NOT NULL CHAR(1)
ARCHIVO BLOB
Create a folder on OS, it should have permission OS Oracle user owner.
su - oracle
mkdir /tmp/fou_archvo
Create a directory object on DB, eg TUKLI_FOU_ARCHVOS, grant permission to a scheme where be the procedure, eg PROD.
connect system/***#DB
CREATE OR REPLACE DIRECTORY TUKLI_FOU_ARCHVOS AS '/tmp/fou_archvos';
GRANT READ, WRITE ON DIRECTORY TUKLI_FOU_ARCHVOS TO PROD;
Crear el TU24X7_ARCHVES_TO_OSFILE.prc en PROD scheme, object
CREATE or replace PROCEDURE TU24X7_ARCHVES_TO_OSFILE(p_from_id number default null )
as
l_file UTL_FILE.FILE_TYPE;
l_buffer RAW(32767);
l_amount BINARY_INTEGER := 32767;
l_pos INTEGER;
--l_blob BLOB;
l_blob_len INTEGER;
l_id varchar2(10);
BEGIN
FOR rFile IN (SELECT archivo, to_char(id)||'_'||nombre filename
FROM fou_archvos
where 1=1
and id >= nvl(p_from_id,id)
)
LOOP
l_pos := 1;
l_blob_len := DBMS_LOB.getlength(rFile.archivo);
l_file := UTL_FILE.fopen('TUKLI_FOU_ARCHVOS',rFile.filename,'wb', 32767);
WHILE l_pos <= l_blob_len LOOP
DBMS_LOB.read(rFile.archivo, l_amount, l_pos, l_buffer);
UTL_FILE.put_raw(l_file, l_buffer, TRUE);
l_pos := l_pos + l_amount;
END LOOP;
-- Close the file.
UTL_FILE.fclose(l_file);
END LOOP;
EXCEPTION
WHEN OTHERS THEN
-- Close the file if something goes wrong.
IF UTL_FILE.is_open(l_file) THEN
UTL_FILE.fclose(l_file);
END IF;
RAISE;
END;
/
Execure using JOB DB
connect PROD/XX#DB
declare
l_jobid number := null;
begin
dbms_job.submit
(
job => l_jobid,
what => 'TU24X7_ARCHVES_TO_OSFILE;',
next_date => sysdate,
interval => null
);
commit;
end;
/