How to make a turtle freeze on certain patch? - random

Question

I want a turtle to move randomly across the interface screen but I need the turtle to freeze if it lands on a 'danger patch'. If the turtle does not land on a 'danger patch' it continues to move. Could someone please help me figure this out?

Answer 1

Levi, in setup, you need to give each turtle a variable that indicates whether the turtle is frozen or not. You should decide what pcolor of patches you want to mean "danger!"
On each go step, if the turtle is not frozen, it can take a step and then check the pcolor of the patch it's on to see if it should be frozen now.
When every turtle is frozen, stop.
The code below will accomplish that.
globals [ danger-color ]
turtles-own [
frozen? ;; each turtle needs its own true-false switch for whether it's frozen.
;; this is a true/false variable so the name ends with "?"
]
to setup
clear-all
;; pick a color you like for dangerous areas. I picked red.
set danger-color red
;; set the bottom half of the viewing area to the danger color
no-display
ask patches with [pycor < 0] [set pcolor danger-color ]
display
;; create 2 big yellow turtles that are not frozen and move them up
create-turtles 2 [
set color yellow
set size 3
setxy random-pxcor 10 ;; put them somewhere on top half of the screen
set frozen? FALSE ;; initially all turtles are not frozen
]
reset-ticks
end
to go
;; see if there is any point in continuing to run
if not any? turtles with [frozen? = FALSE] [stop ]
ask turtles with [ frozen? = FALSE ]
[
set heading random 360
forward 1
;; and check to see if maybe NOW we should be frozen
if pcolor = danger-color
[
set frozen? TRUE
set color blue
]
]
tick
end
Note that I could have just put "red" instead of defining a danger-color, which would save a few keystrokes but that would also make the code harder to update and understand.
if pcolor = danger-color makes it clear what you are testing for, where
if pcolor = red is not so obvious. Trust me, a month later when you come back
to the code, you will appreciate the fact that you did this.
Using a variable like that also means that, if you change your mind about what color should represent danger, you only need to change it exactly one place in the code, and you know where that is. Having "red" hard-coded into your program multiple places makes it hard to find them to update and almost guarantees you will miss one.
Make a comment if this is not clear, and I'll try to explain it better!
Have fun with NetLogo! Thanks for looking for an answer here!