cannot perform dml operation inside a query in plsql - oracle

Question

Here in this below function i want to insert values into table ba_acct_cust_lob_xref according to account number and customer id. And account number im fetching from ch_acct_mast table and customer id from cl_custmast table. How i can achieve this using plsql function. when i tried it is showing error like cannot perform dml opertaion inside a query.
CREATE OR REPLACE FUNCTION AP_EXT_MNT_BAM62
(
var_typ_entity CHAR,
var_cod_acct_no CHAR,
var_cod_cust_id NUMBER,
var_cod_ao_business varchar2,
var_cod_ao_operations varchar2,
var_cod_lob NUMBER
)
RETURN NUMBER
AS
BEGIN
IF var_typ_entity = 'A' THEN
BEGIN
insert into ba_cust_acct_ao_lob_xref
(typ_entity,
Cod_cust_id,
cod_acct_no,
Cod_ao_business,
cod_ao_operations,
cod_lob,
flg_mnt_status,
cod_mnt_action,
cod_last_mnt_makerid,
cod_last_mnt_chkrid,
dat_last_mnt,
ctr_updat_srlno,
COD_ENTITY_VPD)
(select var_typ_entity,
var_cod_cust_id,
var_cod_acct_no,
var_cod_ao_business,
var_cod_ao_operations,
var_cod_lob,
flg_mnt_status,
cod_mnt_action,
cod_last_mnt_makerid,
cod_last_mnt_chkrid,
sysdate,
ctr_updat_srlno,
COD_ENTITY_VPD
from CH_ACCT_MAST
where cod_acct_no=var_cod_acct_no );
EXCEPTION
when no_data_found then
NULL;
END;
END IF;
IF var_typ_entity = 'C' THEN
BEGIN
insert into ba_cust_acct_ao_lob_xref
(typ_entity,
Cod_cust_id,
cod_acct_no,
Cod_ao_business,
cod_ao_operations,
cod_lob,
flg_mnt_status,
cod_mnt_action,
cod_last_mnt_makerid,
cod_last_mnt_chkrid,
dat_last_mnt,
ctr_updat_srlno,
COD_ENTITY_VPD)
(select var_typ_entity,
var_cod_cust_id,
var_cod_acct_no,
var_cod_ao_business,
var_cod_ao_operations,
var_cod_lob,
flg_mnt_status,
cod_mnt_action,
cod_last_mnt_makerid,
cod_last_mnt_chkrid,
sysdate,
ctr_updat_srlno,
COD_ENTITY_VPD
from CI_CUSTMAST
where Cod_cust_id=var_Cod_cust_id );
EXCEPTION
when no_data_found then
NULL;
END;
END IF;
return 1;
END;

Answer 1

Well, you can perform DML in a function and use it in a query, if it were an autonomous transaction. Don't do that, not here.
Here's an example, using this sample table:
SQL> SELECT * FROM test;
ID NAME
---------- --------------------
2 Little
3 Foot
Function is supposed to insert a row into that table (basically, that's what you have):
SQL> CREATE OR REPLACE FUNCTION f_test (par_id IN NUMBER, par_name IN VARCHAR2)
2 RETURN NUMBER
3 IS
4 BEGIN
5 INSERT INTO test (id, name)
6 VALUES (par_id, par_name);
7
8 RETURN 1;
9 END;
10 /
Function created.
Error you got is due to such a code:
SQL> SELECT f_test (5, 'Karthiga') FROM DUAL;
SELECT f_test (5, 'Karthiga') FROM DUAL
*
ERROR at line 1:
ORA-14551: cannot perform a DML operation inside a query
ORA-06512: at "SCOTT.F_TEST", line 5
If it were a PL/SQL procedure, then your function would work:
SQL> DECLARE
2 l_test NUMBER;
3 BEGIN
4 l_test := f_test (5, 'Karthiga');
5 END;
6 /
PL/SQL procedure successfully completed.
Or, as I previously said, if function was an autonomous transaction, you could use it in a query:
SQL> CREATE OR REPLACE FUNCTION f_test (par_id IN NUMBER, par_name IN VARCHAR2)
2 RETURN NUMBER
3 IS
4 PRAGMA AUTONOMOUS_TRANSACTION;
5 BEGIN
6 INSERT INTO test (id, name)
7 VALUES (par_id, par_name);
8
9 COMMIT;
10 RETURN 1;
11 END;
12 /
Function created.
SQL> SELECT f_test (7, 'Twitter') FROM DUAL;
F_TEST(7,'TWITTER')
-------------------
1
SQL>
See? Now it works, but that's not what you should be doing, really.
Result:
SQL> select * from test;
ID NAME
---------- --------------------
2 Little
3 Foot
5 Karthiga --> newly added
7 Twitter --> rows
SQL>
Why do you insist on a function? This is obviously a procedure code. Yes, you're returning 1 just because function has to return something, but there's no evidence that you do need a function. Functions calculate stuff and return the value. You're just inserting a row; that's what procedures do.
So:
CREATE OR REPLACE PROCEDURE AP_EXT_MNT_BAM62 (
var_typ_entity CHAR,
var_cod_acct_no CHAR,
var_cod_cust_id NUMBER,
var_cod_ao_business VARCHAR2,
var_cod_ao_operations VARCHAR2,
var_cod_lob NUMBER)
AS
BEGIN
IF var_typ_entity = 'A'
THEN
BEGIN
INSERT INTO ba_cust_acct_ao_lob_xref (typ_entity,
Cod_cust_id,
cod_acct_no,
Cod_ao_business,
cod_ao_operations,
cod_lob,
flg_mnt_status,
cod_mnt_action,
cod_last_mnt_makerid,
cod_last_mnt_chkrid,
dat_last_mnt,
ctr_updat_srlno,
COD_ENTITY_VPD)
(SELECT var_typ_entity,
var_cod_cust_id,
var_cod_acct_no,
var_cod_ao_business,
var_cod_ao_operations,
var_cod_lob,
flg_mnt_status,
cod_mnt_action,
cod_last_mnt_makerid,
cod_last_mnt_chkrid,
SYSDATE,
ctr_updat_srlno,
COD_ENTITY_VPD
FROM CH_ACCT_MAST
WHERE cod_acct_no = var_cod_acct_no);
EXCEPTION
WHEN NO_DATA_FOUND
THEN
NULL;
END;
END IF;
IF var_typ_entity = 'C'
THEN
BEGIN
INSERT INTO ba_cust_acct_ao_lob_xref (typ_entity,
Cod_cust_id,
cod_acct_no,
Cod_ao_business,
cod_ao_operations,
cod_lob,
flg_mnt_status,
cod_mnt_action,
cod_last_mnt_makerid,
cod_last_mnt_chkrid,
dat_last_mnt,
ctr_updat_srlno,
COD_ENTITY_VPD)
(SELECT var_typ_entity,
var_cod_cust_id,
var_cod_acct_no,
var_cod_ao_business,
var_cod_ao_operations,
var_cod_lob,
flg_mnt_status,
cod_mnt_action,
cod_last_mnt_makerid,
cod_last_mnt_chkrid,
SYSDATE,
ctr_updat_srlno,
COD_ENTITY_VPD
FROM CI_CUSTMAST
WHERE Cod_cust_id = var_Cod_cust_id);
EXCEPTION
WHEN NO_DATA_FOUND
THEN
NULL;
END;
END IF;
END;
If it must return 1, then make it an OUT parameter.